reserve X for set;
reserve G for Group;
reserve H for Subgroup of G;
reserve h,x,y for object;
reserve f for Endomorphism of G;
reserve phi for Automorphism of G;
reserve K for characteristic Subgroup of G;

theorem Th43:
  for phi being Automorphism of G
  holds phi .: commutators G = commutators G
proof
  let phi be Automorphism of G;
  for g being object
  st g in commutators G
  holds g in phi .: commutators G
  proof
    let g be object;
    assume B1: g in commutators G;
    then reconsider g as Element of G;
    consider a,b being Element of G such that
    B2: g = [.a,b.]
    by B1, GROUP_5:58;
    reconsider psi = phi" as Automorphism of G by GROUP_6:62;
    set x = psi.a;
    set y = psi.b;
    set h = [.x,y.];
    dom phi = the carrier of G by FUNCT_2:def 1;
    then B3: h in dom phi & h in commutators G & phi.((phi").g) = g by Th4;
    psi.g = psi.([.a,b.]) by B2
         .= [.psi.a,psi.b.] by GROUP_6:34
         .= h;
    hence thesis by B3, FUNCT_1:def 6;
  end;
  then P1: commutators G c= phi .: commutators G;
  for h being object
  st h in phi .: commutators G
  holds h in commutators G
  proof
    let h be object;
    assume B1: h in phi .: commutators G;
    consider g being object such that
        g in dom phi and
    B2: g in commutators G and
    B3: h = phi.g by B1,FUNCT_1:def 6;
    consider a,b be Element of G such that
    B4: g = [.a,b.] by B2,GROUP_5:58;
    h = phi.g by B3
     .= phi.([.a,b.]) by B4
     .= [.phi.a, phi.b.] by GROUP_6:34;
    hence h in commutators G;
  end;
  then phi .: commutators G c= commutators G;
  hence commutators G = phi .: commutators G by P1,XBOOLE_0:def 10;
end;
