reserve x,y,X,Y for set,
  k,l,n for Nat,
  i,i1,i2,i3,j for Integer,
  G for Group,
  a,b,c,d for Element of G,
  A,B,C for Subset of G,
  H,H1,H2, H3 for Subgroup of G,
  h for Element of H,
  F,F1,F2 for FinSequence of the carrier of G,
  I,I1,I2 for FinSequence of INT;

theorem Th41:
  for G being strict Group holds the carrier of Phi(G) = {a where
  a is Element of G: a is non generating}
proof
  let G be strict Group;
  set A = {a where a is Element of G: a is non generating};
  thus the carrier of Phi(G) c= A
  proof
    defpred P[set,set] means ex H1,H2 being strict Subgroup of G st $1 = H1 &
    $2 = H2 & H1 is Subgroup of H2;
    let x be object;
    assume
A1: x in the carrier of Phi(G);
    then x in Phi(G) by STRUCT_0:def 5;
    then x in G by GROUP_2:40;
    then reconsider a = x as Element of G by STRUCT_0:def 5;
    assume not x in A;
    then a is generating;
    then consider B being Subset of G such that
A2: gr B = G and
A3: gr(B \ {a}) <> G;
    set M = B \ {a};
A4: now
      assume
A5:   a in gr M;
      now
        let b be Element of G;
        b in gr B by A2,STRUCT_0:def 5;
        then consider F being FinSequence of the carrier of G, I such that
        len I = len F and
A6:     rng F c= B and
A7:     b = Product(F |^ I) by Th28;
        rng(F |^ I) c= carr gr M
        proof
          let x be object;
          assume x in rng(F |^ I);
          then consider y being object such that
A8:       y in dom(F |^ I) and
A9:       (F |^ I).y = x by FUNCT_1:def 3;
          reconsider y as Element of NAT by A8;
          len(F |^ I) = len F by Def3;
          then
A10:      y in dom F by A8,FINSEQ_3:29;
          then
A11:      x = (F/.y) |^ @(I/.y) by A9,Def3;
          now
            per cases;
            suppose
              F/.y = a;
              then x in gr M by A5,A11,Th4;
              hence thesis by STRUCT_0:def 5;
            end;
            suppose
              F/.y <> a;
              then
A12:          not F/.y in {a} by TARSKI:def 1;
              F/.y = F.y & F.y in rng F by A10,FUNCT_1:def 3,PARTFUN1:def 6;
              then F/.y in M by A6,A12,XBOOLE_0:def 5;
              then x in gr M by A11,Th4,Th29;
              hence thesis by STRUCT_0:def 5;
            end;
          end;
          hence thesis;
        end;
        hence b in gr M by A7,Th18;
      end;
      hence contradiction by A3,GROUP_2:62;
    end;
    defpred P[Subgroup of G] means M c= carr $1 & not a in $1;
    consider X such that
A13: X c= Subgroups G and
A14: for H being strict Subgroup of G holds H in X iff P[H] from
    SubgrSep;
    M c= carr gr M by Def4;
    then reconsider X as non empty set by A14,A4;
A15: for x,y,z being Element of X st P[x,y] & P[y,z] holds P[x,z]
    proof
      let x,y,z be Element of X;
      given H1,H2 being strict Subgroup of G such that
A16:  x = H1 and
A17:  y = H2 & H1 is Subgroup of H2;
      given H3,H4 being strict Subgroup of G such that
A18:  y = H3 and
A19:  z = H4 and
A20:  H3 is Subgroup of H4;
      H1 is Subgroup of H4 by A17,A18,A20,GROUP_2:56;
      hence thesis by A16,A19;
    end;
A21: for Y st Y c= X & (for x,y being Element of X st x in Y & y in Y
holds P[x,y] or P[y,x]) ex y being Element of X st for x being Element of X st
    x in Y holds P[x,y]
    proof
      let Y;
      assume
A22:  Y c= X;
      set C = {D where D is Subset of G : ex H being strict Subgroup of G st H
      in Y & D = carr H};
      now
        let Z be set;
        assume Z in C;
        then
        ex D being Subset of G st Z = D & ex H being strict Subgroup of G
        st H in Y & D = carr H;
        hence Z c= the carrier of G;
      end;
      then reconsider E = union C as Subset of G by ZFMISC_1:76;
      assume
A23:  for x,y being Element of X st x in Y & y in Y holds P[x,y] or P [y,x];
      now
        per cases;
        suppose
A24:      Y = {};
          set y = the Element of X;
          take y;
          let x be Element of X;
          assume x in Y;
          hence P[x,y] by A24;
        end;
        suppose
A25:      Y <> {};
A26:      now
            let a,b be Element of G;
            assume that
A27:        a in E and
A28:        b in E;
            consider Z being set such that
A29:        a in Z and
A30:        Z in C by A27,TARSKI:def 4;
            consider Z1 being set such that
A31:        b in Z1 and
A32:        Z1 in C by A28,TARSKI:def 4;
            consider D being Subset of G such that
A33:        Z = D and
A34:        ex H being strict Subgroup of G st H in Y & D = carr H by A30;
            consider B being Subset of G such that
A35:        Z1 = B and
A36:        ex H being strict Subgroup of G st H in Y & B = carr H by A32;
            consider H1 being Subgroup of G such that
A37:        H1 in Y and
A38:        D = carr H1 by A34;
            consider H2 being Subgroup of G such that
A39:        H2 in Y and
A40:        B = carr H2 by A36;
            now
              per cases by A22,A23,A37,A39;
              suppose
                P[H1,H2];
                then carr H1 c= the carrier of H2 by GROUP_2:def 5;
                then a * b in carr H2 by A29,A33,A38,A31,A35,A40,GROUP_2:74;
                hence a * b in E by A32,A35,A40,TARSKI:def 4;
              end;
              suppose
                P[H2,H1];
                then carr H2 c= the carrier of H1 by GROUP_2:def 5;
                then a * b in carr H1 by A29,A33,A38,A31,A35,A40,GROUP_2:74;
                hence a * b in E by A30,A33,A38,TARSKI:def 4;
              end;
            end;
            hence a * b in E;
          end;
A41:      now
            let a be Element of G;
            assume a in E;
            then consider Z being set such that
A42:        a in Z and
A43:        Z in C by TARSKI:def 4;
            consider D being Subset of G such that
A44:        Z = D and
A45:        ex H being strict Subgroup of G st H in Y & D = carr H by A43;
            consider H1 being Subgroup of G such that
            H1 in Y and
A46:        D = carr H1 by A45;
            a" in carr H1 by A42,A44,A46,GROUP_2:75;
            hence a" in E by A43,A44,A46,TARSKI:def 4;
          end;
          set s = the Element of Y;
A47:      s in X by A22,A25;
          then reconsider s as strict Subgroup of G by A13,GROUP_3:def 1;
A48:      carr s in C by A25;
          then
A49:      carr s c= E by ZFMISC_1:74;
          E <> {} by A48,ORDERS_1:6;
          then consider H being strict Subgroup of G such that
A50:      the carrier of H = E by A26,A41,GROUP_2:52;
A51:      now
            assume a in H;
            then a in E by A50,STRUCT_0:def 5;
            then consider Z being set such that
A52:        a in Z and
A53:        Z in C by TARSKI:def 4;
            consider D being Subset of G such that
A54:        Z = D and
A55:        ex H being strict Subgroup of G st H in Y & D = carr H by A53;
            consider H1 being strict Subgroup of G such that
A56:        H1 in Y and
A57:        D = carr H1 by A55;
            not a in H1 by A14,A22,A56;
            hence contradiction by A52,A54,A57,STRUCT_0:def 5;
          end;
          M c= carr s by A14,A47;
          then
A58:      M c= E by A49;
          the carrier of H = carr H;
          then reconsider y = H as Element of X by A14,A58,A50,A51;
          take y;
          let x be Element of X;
          assume
A59:      x in Y;
          x in Subgroups G by A13;
          then reconsider K = x as strict Subgroup of G by GROUP_3:def 1;
          take K,H;
          thus x = K & y = H;
          carr K = the carrier of K;
          then the carrier of K in C by A59;
          hence K is Subgroup of H by A50,GROUP_2:57,ZFMISC_1:74;
        end;
      end;
      hence thesis;
    end;
A60: now
      let x be Element of X;
      x in Subgroups G by A13;
      hence x is strict Subgroup of G by GROUP_3:def 1;
    end;
A61: for x being Element of X holds P[x,x]
    proof
      let x be Element of X;
      reconsider H = x as strict Subgroup of G by A60;
      H is Subgroup of H by GROUP_2:54;
      hence thesis;
    end;
A62: for x,y being Element of X st P[x,y] & P[y,x] holds x = y by GROUP_2:55;
    consider s being Element of X such that
A63: for y being Element of X st s <> y holds not P[s,y] from
    ORDERS_1:sch 1 (A61,A62,A15,A21);
    reconsider H = s as strict Subgroup of G by A60;
    H is maximal
    proof
      not a in H by A14;
      hence the multMagma of H <> the multMagma of G by STRUCT_0:def 5;
      let K be strict Subgroup of G;
      assume that
A64:  K <> the multMagma of H and
A65:  H is Subgroup of K and
A66:  K <> the multMagma of G;
A67:  M c= carr H by A14;
      the carrier of H c= the carrier of K by A65,GROUP_2:def 5;
      then
A68:  M c= carr K by A67;
      now
A69:    B c= M \/ {a}
        proof
          let x be object;
          assume
A70:      x in B;
          now
            per cases;
            suppose
              x = a;
              then x in {a} by TARSKI:def 1;
              hence thesis by XBOOLE_0:def 3;
            end;
            suppose
              x <> a;
              then not x in {a} by TARSKI:def 1;
              then x in M by A70,XBOOLE_0:def 5;
              hence thesis by XBOOLE_0:def 3;
            end;
          end;
          hence thesis;
        end;
        assume a in K;
        then a in carr K by STRUCT_0:def 5;
        then {a} c= carr K by ZFMISC_1:31;
        then M \/ {a} c= carr K by A68,XBOOLE_1:8;
        then gr B is Subgroup of gr carr K by A69,Th32,XBOOLE_1:1;
        then G is Subgroup of K by A2,Th31;
        hence contradiction by A66,GROUP_2:55;
      end;
      then reconsider v = K as Element of X by A14,A68;
      not P[s,v] by A63,A64;
      hence thesis by A65;
    end;
    then Phi(G) is Subgroup of H by Th40;
    then the carrier of Phi(G) c= the carrier of H by GROUP_2:def 5;
    then x in H by A1,STRUCT_0:def 5;
    hence thesis by A14;
  end;
  let x be object;
  assume x in A;
  then consider a being Element of G such that
A71: x = a and
A72: a is non generating;
  now
    per cases;
    suppose
      for H being strict Subgroup of G holds H is not maximal;
      then Phi(G) = G by Def7;
      hence thesis by A71;
    end;
    suppose
A73:  ex H being strict Subgroup of G st H is maximal;
      now
        let H be strict Subgroup of G;
        assume
A74:    H is maximal;
        now
          assume
A75:      not a in H;
          carr H /\ {a} c= {}
          proof
            let x be object;
            assume
A76:        x in carr H /\ {a};
            then x in {a} by XBOOLE_0:def 4;
            then
A77:        x = a by TARSKI:def 1;
            x in carr H by A76,XBOOLE_0:def 4;
            hence thesis by A75,A77,STRUCT_0:def 5;
          end;
          then carr H /\ {a} = {};
          then
A78:      carr H misses {a};
          (carr H \/ {a}) \ {a} = carr H \ {a} by XBOOLE_1:40
            .= carr H by A78,XBOOLE_1:83;
          then
A79:      gr((carr H \/ {a}) \ {a}) = H by Th31;
A80:      H <> G by A74;
          gr(carr H \/ {a}) = G by A74,A75,Th37;
          hence contradiction by A72,A79,A80;
        end;
        hence a in H;
      end;
      then a in Phi(G) by A73,Th38;
      hence thesis by A71,STRUCT_0:def 5;
    end;
  end;
  hence thesis;
end;
