reserve x,O for set,
  o for Element of O,
  G,H,I for GroupWithOperators of O,
  A, B for Subset of G,
  N for normal StableSubgroup of G,
  H1,H2,H3 for StableSubgroup of G,
  g1,g2 for Element of G,
  h1,h2 for Element of H1,
  h for Homomorphism of G,H;

theorem Th41:
  H1 /\ N is normal StableSubgroup of H1 & N /\ H1 is normal
  StableSubgroup of H1
proof
  thus H1 /\ N is normal StableSubgroup of H1
  proof
    reconsider A = H1 /\ N as StableSubgroup of H1 by Lm33;
    now
      reconsider N9=the multMagma of N as normal Subgroup of G by Lm6;
      let H be strict Subgroup of H1;
      assume
A1:   H = the multMagma of A;
      now
        let b be Element of H1;
        thus b * H c= H * b
        proof
          let x be object;
          assume x in b * H;
          then consider a be Element of H1 such that
A2:       x = b * a and
A3:       a in H by GROUP_2:103;
          reconsider a9 = a, b9 = b as Element of G by Th2;
          reconsider x9 = x as Element of H1 by A2;
A4:       b9" = b" by Th6;
          a in the carrier of A by A1,A3,STRUCT_0:def 5;
          then a in carr(H1) /\ carr(N) by Def25;
          then a in carr N9 by XBOOLE_0:def 4;
          then
A5:       a in N9 by STRUCT_0:def 5;
          x = b9 * a9 by A2,Th3;
          then
A6:       x in b9 * N9 by A5,GROUP_2:103;
          b9 * N9 c= N9 * b9 by GROUP_3:118;
          then consider b1 be Element of G such that
A7:       x = b1 * b9 and
A8:       b1 in N9 by A6,GROUP_2:104;
          reconsider x99 = x as Element of G by A7;
          b1 = x99 * b9" by A7,GROUP_1:14;
          then
A9:       b1 = x9 * b" by A4,Th3;
          then reconsider b19 = b1 as Element of H1;
          b1 in the carrier of N by A8,STRUCT_0:def 5;
          then b1 in carr(H1) /\ carr(N) by A9,XBOOLE_0:def 4;
          then b19 in the carrier of A by Def25;
          then
A10:      b19 in H by A1,STRUCT_0:def 5;
          b19 * b = x by A7,Th3;
          hence thesis by A10,GROUP_2:104;
        end;
      end;
      hence H is normal by GROUP_3:118;
    end;
    hence thesis by Def10;
  end;
  hence thesis;
end;
