 reserve h,h1 for 0-convergent non-zero Real_Sequence,
         c,c1 for constant Real_Sequence;

theorem
  for c be Real, f,F,G be PartFunc of REAL,REAL, I be non empty Interval st
   I c= dom f & F is_antiderivative_of f,I &
   I c= dom G & (for x be Real st x in I holds G.x = F.x + c) holds
   G is_antiderivative_of f,I
proof
    let c be Real, f,F,G be PartFunc of REAL,REAL, I be non empty Interval;
    assume that
A1:  I c= dom f and
A2:  F is_antiderivative_of f,I and
A3: I c= dom G and
A4:  for x be Real st x in I holds G.x = F.x + c;

A5: I c= dom F & inf I < sup I by A2,FDIFF_12:def 1;

    reconsider c0=c as Element of REAL by XREAL_0:def 1;
    deffunc F(Element of REAL) = c0;
    consider F0 be Function of REAL,REAL such that
A6:  for x be Element of REAL holds F0.x = F(x) from FUNCT_2:sch 4;

    set G0 = F0|I;
    dom F0 = REAL by FUNCT_2:def 1; then
A7: dom G0 = I by RELAT_1:62;
A8: now let y be object;
     assume y in rng G0; then
     consider x be Element of REAL such that
A9:   x in dom G0 & G0.x = y by PARTFUN1:3;
     G0.x = F0.x by A9,FUNCT_1:47; then
     G0.x = c by A6;
     hence y in {c} by A9,TARSKI:def 1;
    end; then
A10: rng G0 c= {c};

    now let y be object;
     assume y in {c}; then
A11:  y = c by TARSKI:def 1;
     consider x be object such that
A12:   x in I by XBOOLE_0:def 1;
     reconsider x as Element of REAL by A12;
     G0.x = F0.x by A12,FUNCT_1:49; then
     G0.x = c by A6;
     hence y in rng G0 by A7,A12,A11,FUNCT_1:3;
    end; then
    {c} c= rng G0; then
A13:rng G0 = {c} by A10,XBOOLE_0:def 10; then
A14:G0 is_differentiable_on_interval I &
    for x be Real st x in I holds (G0`\I).x = 0 by A5,A7,FDIFF_12:15;

A15:dom(F|I) = I by A5,RELAT_1:62;
A16:dom(F|I + G0) = dom(F|I) /\ dom G0 by VALUED_1:def 1;

A17: F|I is_differentiable_on_interval I by A2,Th15;

A18: dom(f|I) = I by A1,RELAT_1:62;

    now let x be Element of REAL;
     assume
A19:  x in dom(G|I); then
     (G|I).x = G.x by FUNCT_1:47; then
A20: (G|I).x = F.x + c by A19,A4;
A21: F.x = (F|I).x by A19,A15,FUNCT_1:47;
     G0.x in {c} by A7,A19,A8,FUNCT_1:3; then
     G0.x = c by TARSKI:def 1;
     hence (G|I).x = ((F|I)+G0).x by A16,A15,A7,A19,A20,A21,VALUED_1:def 1;
    end; then
A22: G|I = F|I + G0 by A16,A15,A7,A3,RELAT_1:62,PARTFUN1:5; then
A23: G|I is_differentiable_on_interval I by A16,A15,A7,A14,A17
,FDIFF_12:19; then
A24: G is_differentiable_on_interval I by Th15; then
A25: dom(G`\I) = I by FDIFF_12:def 2;
    now let x be Element of REAL;
     assume
A26:   x in dom(G`\I); then
A27:  (G0`\I).x = 0 by A13,A25,A5,A7,FDIFF_12:15;
     G`\I = (G|I)`\I by A24,Th16; then
     (G`\I).x = ((F|I)`\I).x + (G0`\I).x
       by A22,A25,A26,A16,A15,A7,A17,A14,FDIFF_12:19;
     hence (G`\I).x = (f|I).x by A27,A2,Th16;
    end;
    hence G is_antiderivative_of f,I by A23,A18,A25,Th15,PARTFUN1:5;
end;
