reserve

  k,n,m,i,j for Element of NAT,
  K for Field;
reserve L for non empty addLoopStr;
reserve G for non empty multLoopStr;

theorem Th41:
  for A being Matrix of n,K st n>0 & A*(1,1)<>0.K ex P,Q being
Matrix of n,K st P is invertible & Q is invertible & (P*A*Q)*(1,1)=1.K & (for i
st 1<i & i<=n holds (P*A*Q)*(i,1)= 0.K)& for j st 1<j & j<=n holds (P*A*Q)*(1,j
  )= 0.K
proof
  let A be Matrix of n,K;
  assume that
A1: n>0 and
A2: A*(1,1)<>0.K;
  consider P being Matrix of n,K such that
A3: P is invertible and
A4: (P*A)*(1,1)=1.K and
A5: for i st 1<i & i<=n holds (P*A)*(i,1)= 0.K and
  for j st 1<j & j<=n & A*(1,j)= 0.K holds (P*A)*(1,j)= 0.K by A1,A2,Th40;
  consider Q being Matrix of n,K such that
A6: Q is invertible & ((P*A)*Q)*(1,1)=1.K & for j st 1<j & j<=n holds ((
  P*A) *Q)*(1,j)= 0.K and
A7: for i st 1<i & i<=n & (P*A)*(i,1)= 0.K holds ((P*A)*Q)*(i,1)= 0.K by A1,A4
,Th39;
  for i st 1<i & i<=n holds (P*A*Q)*(i,1)= 0.K
  proof
    let i;
    assume
A8: 1<i & i<=n;
    then (P*A)*(i,1)= 0.K by A5;
    hence thesis by A7,A8;
  end;
  hence thesis by A3,A6;
end;
