reserve F for RealNormSpace;
reserve G for RealNormSpace;
reserve y,X for set;
reserve x,x0,x1,x2,g,g1,g2,r,r1,s,p,p1,p2 for Real;
reserve i,m,k for Element of NAT;
reserve n,k for non zero Element of NAT;
reserve Y for Subset of REAL;
reserve Z for open Subset of REAL;
reserve s1,s3 for Real_Sequence;
reserve seq,seq1 for sequence of G;
reserve f,f1,f2 for PartFunc of REAL,REAL n;
reserve g,g1,g2 for PartFunc of REAL,REAL-NS n;
reserve h for 0-convergent non-zero Real_Sequence;
reserve c for constant Real_Sequence;
reserve GR,R for RestFunc of REAL-NS n;
reserve DFG,L for LinearFunc of REAL-NS n;

theorem Th41:
  for J be Function of REAL-NS 1,REAL st J = proj(1,1) holds
  (for R being RestFunc of REAL-NS n holds
      R*J is RestFunc of REAL-NS 1,REAL-NS n) &
  for L being LinearFunc of REAL-NS n holds
     L*J is Lipschitzian LinearOperator of REAL-NS 1,REAL-NS n
proof
  let J be Function of REAL-NS 1,REAL;
  assume A1: J=proj(1,1);
  thus
  for R being RestFunc of REAL-NS n holds
  R*J is RestFunc of REAL-NS 1,REAL-NS n
  proof
    let R be RestFunc of REAL-NS n;
A2: R is total by NDIFF_3:def 1;
    reconsider R0=R as Function of REAL,REAL n by A2,REAL_NS1:def 4;
    reconsider R1 = R0*J as PartFunc of REAL-NS 1,REAL-NS n
           by REAL_NS1:def 4;
    for h be (0.(REAL-NS 1))-convergent
    sequence of REAL-NS 1 st h is non-zero holds ||.h.||"(#)(R1/*h
    ) is convergent & lim(||.h.||"(#)(R1/*h)) = 0.(REAL-NS n)
    proof
      let h be (0.(REAL-NS 1))-convergent sequence of REAL-NS 1;
      assume A3: h is non-zero;
A4:   lim h = 0.(REAL-NS 1) by NDIFF_1:def 4;
      deffunc F(Nat)=J.(h.$1);
      consider s be Real_Sequence such that
A5:   for n be Nat holds s.n = F(n) from SEQ_1:sch 1;
A6:   h is convergent by NDIFF_1:def 4;
A7:   now
        let p be Real;
        assume 0 < p;
        then consider m be Nat such that
A8:     for n be Nat st m <= n holds ||. h.n - 0.(REAL-NS
        1).|| < p by A6,A4,NORMSP_1:def 7;
        take m;
        now
          let n be Nat;
          assume m <= n;
          then ||. h.n - 0.(REAL-NS 1).|| < p by A8;
          then
A9:      ||. h.n .|| < p by RLVECT_1:13;
          s.n = J.(h.n) by A5;
          hence |.s.n-0 .| < p by A1,A9,PDIFF_1:4;
        end;
        hence for n be Nat st m <= n holds |.s.n-0 .|< p;
      end;
      then
A10:  s is convergent by SEQ_2:def 6;
      then
A11:  lim s = 0 by A7,SEQ_2:def 7;
      now
        let x be object;
        assume x in NAT;
        then reconsider n=x as Element of NAT;
A12:    0 <= |.s.n.| by COMPLEX1:46;
        h.n <> 0.(REAL-NS 1) by A3,NDIFF_1:6;
        then
A13:    ||. h.n .|| <> 0 by NORMSP_0:def 5;
        s.n = J.(h.n) by A5;
        then |.s.n.| <> 0 by A1,A13,PDIFF_1:4;
        hence s.x <> 0 by A12,COMPLEX1:47;
      end;
      then s is non-zero by SEQ_1:4;
      then reconsider s as 0-convergent non-zero Real_Sequence
      by A10,A11,FDIFF_1:def 1;
      now
        reconsider f1=R1 as Function;
        let n be Element of NAT;
A14:    rng h c= the carrier of REAL-NS 1;
        (R/*s).n =R.(s.n) by A2,FUNCT_2:115;
        then
A15:    (R/*s).n =R.(J.(h.n)) by A5;
        NAT = dom h by FUNCT_2:def 1;
        then
A16:    R1.(h.n) =(f1*h).n by FUNCT_1:13;
        rng h c= dom R1 by A14,FUNCT_2:def 1;
        then
A17:    R1.(h.n) =(R1/*h).n by A16,FUNCT_2:def 11;
A18:    s.n = J.(h.n) by A5;
         ||. ||.h.||"(#)(R1/*h).|| .n = ||.(||.h.||"(#)(R1/*h)).n .|| by
NORMSP_0:def 4
          .= ||.(||.h.||").n * (R1/*h).n .|| by NDIFF_1:def 2
          .= |.(||.h.||").n.| * ||.(R1/*h).n .|| by NORMSP_1:def 1
          .= |.(||.h.||.n)".| * ||.(R1/*h).n .|| by VALUED_1:10
          .= |.||.h.n.||".| * ||.(R1/*h).n .|| by NORMSP_0:def 4
          .= ||.h.n .||" *||.(R1/*h).n .|| by ABSVALUE:def 1
          .= (|.s.n.|)" *||.(R1/*h).n .|| by A1,A18,PDIFF_1:4
          .= (|.s.n.|)" *||.(R/*s).n .|| by A17,A15,FUNCT_2:15
          .= ((abs s).n)"*||.(R/*s).n .|| by SEQ_1:12
          .= ((abs s)".n)*||.(R/*s).n .|| by VALUED_1:10
          .=(|.s".|.n)*||.(R/*s).n .|| by SEQ_1:54
          .=|.s".n.|*||.(R/*s).n .|| by SEQ_1:12
          .= ||. (s".n)*(R/*s).n .|| by NORMSP_1:def 1
          .= ||. (s"(#)(R/*s)).n .|| by NDIFF_1:def 2
          .= ||. (s"(#)(R/*s)) .||.n by NORMSP_0:def 4;
        hence ||. ||.h.||"(#)(R1/*h) .|| .n = ||. (s"(#)(R/*s)) .||.n;
      end;
      then
A19:  ||. ||.h.||"(#)(R1/*h) .|| = ||. s"(#)(R/*s) .|| by FUNCT_2:63;
A20:  lim(s"(#)(R/*s))=0.(REAL-NS n) by NDIFF_3:def 1;
A21:  s"(#)(R/*s) is convergent by NDIFF_3:def 1;
A22:  lim ||. s"(#)(R/*s) .|| = ||.0.(REAL-NS n).|| by A20,A21,LOPBAN_1:20
                            .= 0;
A23:  ||. s"(#)(R/*s) .|| is convergent by A21,NORMSP_1:23;
A24:  now
        let p be Real;
        assume 0 < p;
        then consider n0 be Nat such that
A25:    for m be Nat st n0 <= m holds |.||. ||.h.||"(#)(
        R1/*h).||.m - 0 .| < p by A19,A23,A22,SEQ_2:def 7;
        take n0;
        hereby
          let m be Nat;
          assume n0 <= m;
          then |.||. ||.h.||"(#)(R1/*h).|| .m - 0 .| < p by A25;
          then
A26:      |. ||.( ||.h.||"(#)(R1/*h)).m.|| .| < p by NORMSP_0:def 4;
         ||.(||.h.||"(#)(R1/*h)).m.|| < p by A26,ABSVALUE:def 1;
          hence ||.(||.h.||"(#)(R1/*h)).m -0.(REAL-NS n) .|| < p
                    by RLVECT_1:13;
        end;
      end;
      then ||.h.||"(#)(R1/*h) is convergent by NORMSP_1:def 6;
      hence thesis by A24,NORMSP_1:def 7;
    end;
    hence thesis by NDIFF_1:def 5;
  end;
  let L be LinearFunc of REAL-NS n;
  consider r be Point of REAL-NS n such that
A27: for p be Real holds L/.p = p*r by NDIFF_3:def 2;
   reconsider L0 = L as Function of REAL,REAL n by REAL_NS1:def 4;
   set K = ||.r.||;
    reconsider L1 = L*J as Function of REAL-NS 1,REAL-NS n;
A28: dom L1 = REAL 1 by Lm1,FUNCT_2:def 1;
A29: now
      let x,y be Point of REAL-NS 1;
      L1.(x+y) =L/.(J.(x+y)) by Lm1,A28,FUNCT_1:12;
      then L1.(x+y) = L/.((J.x+J.y)) by A1,PDIFF_1:4;
      then L1.(x+y) = (J.x+J.y)*r by A27;
      then L1.(x+y) = (J.x)*r+(J.y)*r by RLVECT_1:def 6;
      then L1.(x+y) = L/.(J.x)+(J.y)*r by A27;
      then
A30:  L1.(x+y) = L/.(J.x)+L/.(J.y) by A27;
      L/.(J.x) = L1.x by Lm1,A28,FUNCT_1:12;
      hence L1.(x+y) =L1.x + L1.y by Lm1,A28,A30,FUNCT_1:12;
    end;
    now
      let x be Point of REAL-NS 1, a be Real;
      L1.(a*x) = L/.(J.(a*x)) by Lm1,A28,FUNCT_1:12;
      then L1.(a*x) = L/.(a*(J.x)) by A1,PDIFF_1:4;
      then L1.(a*x) = (a*(J.x))*r by A27;
      then
A31:  L1.(a*x) = a*((J.x)*r) by RLVECT_1:def 7;
      L/.(J.x) = L1.x by Lm1,A28,FUNCT_1:12;
      hence L1.(a*x) =a*(L1.x) by A31,A27;
    end;
    then reconsider L1 as LinearOperator of REAL-NS 1,REAL-NS n by A29,
LOPBAN_1:def 5,VECTSP_1:def 20;
    now
      let x be Point of REAL-NS 1;
      ||. L1.x .|| =||. L/.(J.x) .|| by Lm1,A28,FUNCT_1:12;
      then ||. L1.x .|| =||. (J.x)*r .|| by A27;
      then ||. L1.x .|| =||.r.||*|.J.x .| by NORMSP_1:def 1;
      hence ||. L1.x .|| <= K* ||.x.|| by A1,PDIFF_1:4;
    end;
    hence thesis by LOPBAN_1:def 8;
  end;
