reserve x,x0,x1,y,y0,y1,z,z0,z1,r,r1,s,p,p1 for Real;
reserve u,u0 for Element of REAL 3;
reserve n for Element of NAT;
reserve s1 for Real_Sequence;
reserve f,f1,f2 for PartFunc of REAL 3,REAL;
reserve R,R1 for RestFunc;
reserve L,L1 for LinearFunc;

theorem
  for u0 being Element of REAL 3 for N being Neighbourhood of proj(2,3).u0 st
  f is_hpartial_differentiable`22_in u0 &
  N c= dom SVF1(2,pdiff1(f,2),u0) holds
  for h be 0-convergent non-zero Real_Sequence, c be constant Real_Sequence
  st rng c = {proj(2,3).u0} & rng (h+c) c= N holds
  h"(#)(SVF1(2,pdiff1(f,2),u0)/*(h+c) - SVF1(2,pdiff1(f,2),u0)/*c)
    is convergent &
  hpartdiff22(f,u0)
  = lim (h"(#)(SVF1(2,pdiff1(f,2),u0)/*(h+c) - SVF1(2,pdiff1(f,2),u0)/*c))
proof
    let u0 be Element of REAL 3;
    let N be Neighbourhood of proj(2,3).u0;
    assume
A1: f is_hpartial_differentiable`22_in u0 & N c= dom SVF1(2,pdiff1(f,2),u0);
    let h be 0-convergent non-zero Real_Sequence,
    c be constant Real_Sequence such that
A2: rng c = {proj(2,3).u0} & rng (h+c) c= N;
A3: pdiff1(f,2) is_partial_differentiable_in u0,2 by A1,Th23;
    consider x0,y0,z0 being Element of REAL such that
A4: u0 = <*x0,y0,z0*> by FINSEQ_2:103;
    partdiff(pdiff1(f,2),u0,2)
    = diff(SVF1(2,pdiff1(f,2),u0),y0) by A4,PDIFF_4:20
   .= hpartdiff22(f,u0) by A1,A4,Th14;
    hence thesis by A1,A2,A3,PDIFF_4:26;
end;
