reserve a, b, r, s for Real;

theorem Th41:
  r <= s implies for X being Subset of Closed-Interval-TSpace(r,s)
  st X = [.a,b.[ & r < a & b <= s holds Int X = ].a,b.[
proof
  set L = Closed-Interval-TSpace(r,s);
  set c = (r+a)/2;
  set C1 = R^1(].c,b.[);
A1: C1 = ].c,b.[ by TOPREALB:def 3;
  assume r <= s;
  then
A2: the carrier of L = [.r,s.] by TOPMETR:18;
  let X be Subset of Closed-Interval-TSpace(r,s) such that
A3: X = [.a,b.[ and
A4: r < a and
A5: b <= s;
A6: r < c by A4,XREAL_1:226;
A7: C1 c= the carrier of L
  proof
    let x be object;
    assume
A8: x in C1;
    then reconsider x as Real;
    x < b by A1,A8,XXREAL_1:4;
    then
A9: x <= s by A5,XXREAL_0:2;
    c < x by A1,A8,XXREAL_1:4;
    then r <= x by A6,XXREAL_0:2;
    hence thesis by A2,A9,XXREAL_1:1;
  end;
  reconsider A = X as Subset of R^1 by PRE_TOPC:11;
A10: c < a by A4,XREAL_1:226;
  A c= C1
  proof
    let x be object;
    assume
A11: x in A;
    then reconsider x as Real;
    a <= x by A3,A11,XXREAL_1:3;
    then
A12: c < x by A10,XXREAL_0:2;
    x < b by A3,A11,XXREAL_1:3;
    hence thesis by A1,A12,XXREAL_1:4;
  end;
  then Int A = Int X by A7,TOPS_3:57;
  hence thesis by A3,Th38;
end;
