reserve i,j,k,n,m for Nat;
reserve p,q for Point of TOP-REAL 2;
reserve G for Go-board;
reserve C for Subset of TOP-REAL 2;

theorem
  for f being clockwise_oriented non constant standard
  special_circular_sequence st f/.1 = N-min L~f holds LeftComp SpStSeq L~f c=
  LeftComp f
proof
  let f be clockwise_oriented non constant standard special_circular_sequence
   such that
A1: f/.1 = N-min L~f;
  defpred X[Element of TOP-REAL 2] means $1`2 < S-bound L~f;
  reconsider P1 = { p: X[p] } as Subset of TOP-REAL 2 from DOMAIN_1:sch 7;
  defpred X[Element of TOP-REAL 2] means $1`2 > N-bound L~f;
  reconsider P2 = { p: X[p] } as Subset of TOP-REAL 2 from DOMAIN_1:sch 7;
  defpred X[Element of TOP-REAL 2] means $1`1 > E-bound L~f;
  reconsider P3 = { p: X[p] } as Subset of TOP-REAL 2 from DOMAIN_1:sch 7;
  defpred X[Element of TOP-REAL 2] means $1`1 < W-bound L~f;
  reconsider P4 = { p: X[p] } as Subset of TOP-REAL 2 from DOMAIN_1:sch 7;
A2: W-bound L~SpStSeq L~f = W-bound L~f by SPRECT_1:58;
  for p st p in P2 holds p`2 > (GoB f)*(1, width GoB f)`2
  proof
    let p;
    assume p in P2;
    then ex q st p = q & q`2 > N-bound L~f;
    hence thesis by JORDAN5D:40;
  end;
  then
A3: P2 misses L~f by GOBOARD8:24;
A4: 1+1 <= len f by GOBOARD7:34,XXREAL_0:2;
A5: width GoB f -' 1 + 1 = width GoB f by GOBRD11:34,XREAL_1:235;
  consider i such that
A6: 1 <= i and
A7: i < len GoB f and
A8: N-min L~f = (GoB f)*(i,width GoB f) by Th28;
A9: i+1 <= len GoB f by A7,NAT_1:13;
A10: i in dom GoB f by A6,A7,FINSEQ_3:25;
  then
A11: f/.2 = (GoB f)*(i+1,width GoB f) by A1,A8,Th29;
A12: width GoB f >= 1 by GOBRD11:34;
  then
A13: [i,width GoB f] in Indices GoB f by A6,A7,MATRIX_0:30;
A14: 1 <= i+1 by A6,NAT_1:13;
  then
A15: (f/.2)`2 = ((GoB f)*(1,width GoB f))`2 by A11,A12,A9,GOBOARD5:1
    .= (N-min L~f)`2 by A6,A7,A8,A12,GOBOARD5:1
    .= N-bound L~f by EUCLID:52;
  set a = 1/2*((GoB f)*(i,width GoB f)+(GoB f)*(i+1,width GoB f))+|[0,1]|, q =
  1/2*((GoB f)*(i,width GoB f)+(GoB f)*(i+1,width GoB f));
A16: a`2 = q`2+|[0,1]|`2 by TOPREAL3:2
    .= q`2+1 by EUCLID:52;
  q`2 = (1/2*((GoB f)*(i,width GoB f)+f/.2))`2 by A1,A8,A10,Th29
    .= 1/2*(f/.1+f/.2)`2 by A1,A8,TOPREAL3:4
    .= 1/2*((f/.1)`2+(f/.2)`2) by TOPREAL3:2
    .= 1/2*(N-bound L~f+N-bound L~f) by A1,A15,EUCLID:52
    .= N-bound L~f;
  then a`2 > 0 + N-bound L~f by A16,XREAL_1:8;
  then
A17: a`2 > N-bound L~SpStSeq L~f by SPRECT_1:60;
  LeftComp SpStSeq L~f = {p : not(W-bound L~SpStSeq L~f <= p`1 & p`1 <=
E-bound L~SpStSeq L~f & S-bound L~SpStSeq L~f <= p`2 & p`2 <= N-bound L~SpStSeq
  L~f)} by Th37;
  then
A18: a in LeftComp SpStSeq L~f by A17;
  [i+1,width GoB f] in Indices GoB f by A12,A14,A9,MATRIX_0:30;
  then left_cell(f,1) = cell(GoB f,i,width GoB f) by A1,A8,A11,A5,A4,A13,
GOBOARD5:28;
  then
A19: Int cell(GoB f,i,width GoB f) c= LeftComp f by GOBOARD9:def 1;
  a in Int cell(GoB f,i,width GoB f) by A6,A9,GOBOARD6:32;
  then
A20: LeftComp f meets LeftComp SpStSeq L~f by A19,A18,XBOOLE_0:3;
A21: S-bound L~SpStSeq L~f = S-bound L~f by SPRECT_1:59;
  for p st p in P4 holds p`1 < (GoB f)*(1,1)`1
  proof
    let p;
    assume p in P4;
    then ex q st p = q & q`1 < W-bound L~f;
    hence thesis by JORDAN5D:37;
  end;
  then
A22: P4 misses L~f by GOBOARD8:21;
  for p st p in P3 holds p`1 > (GoB f)*(len GoB f,1)`1
  proof
    let p;
    assume p in P3;
    then ex q st p = q & q`1 > E-bound L~f;
    hence thesis by JORDAN5D:39;
  end;
  then P3 misses L~f by GOBOARD8:22;
  then
A23: P3 \/ P4 misses L~f by A22,XBOOLE_1:70;
  LeftComp SpStSeq L~f is_a_component_of (L~SpStSeq L~f)` by GOBOARD9:def 1;
  then consider B1 being Subset of (TOP-REAL 2)|(L~SpStSeq L~f)` such that
A24: B1 = LeftComp SpStSeq L~f and
A25: B1 is a_component by CONNSP_1:def 6;
  B1 is connected by A25,CONNSP_1:def 5;
  then
A26: LeftComp SpStSeq L~f is connected by A24,CONNSP_1:23;
A27: E-bound L~SpStSeq L~f = E-bound L~f by SPRECT_1:61;
A28: N-bound L~SpStSeq L~f = N-bound L~f by SPRECT_1:60;
A29: LeftComp SpStSeq L~f = P1 \/ P2 \/ (P3 \/ P4)
  proof
    thus LeftComp SpStSeq L~f c= P1 \/ P2 \/ (P3 \/ P4)
    proof
      let x be object;
      assume x in LeftComp SpStSeq L~f;
      then
      x in { p : not(W-bound L~f <= p`1 & p`1 <= E-bound L~f & S-bound L~
      f <= p`2 & p`2 <= N-bound L~f)} by A28,A2,A21,A27,Th37;
      then ex p st p = x & not(W-bound L~f <= p`1 & p`1 <= E-bound L~f &
      S-bound L~f <= p`2 & p`2 <= N-bound L~f);
      then x in P1 or x in P2 or x in P3 or x in P4;
      then x in P1 \/ P2 or x in P3 \/ P4 by XBOOLE_0:def 3;
      hence thesis by XBOOLE_0:def 3;
    end;
    let x be object;
    assume x in P1 \/ P2 \/ (P3 \/ P4);
    then
A30: x in P1 \/ P2 or x in P3 \/ P4 by XBOOLE_0:def 3;
    per cases by A30,XBOOLE_0:def 3;
    suppose
      x in P1;
      then ex p st x = p & p`2 < S-bound L~f;
      hence thesis by A21,Th40;
    end;
    suppose
      x in P2;
      then ex p st x = p & p`2 > N-bound L~f;
      hence thesis by A28,Th40;
    end;
    suppose
      x in P3;
      then ex p st x = p & p`1 > E-bound L~f;
      hence thesis by A27,Th40;
    end;
    suppose
      x in P4;
      then ex p st x = p & p`1 < W-bound L~f;
      hence thesis by A2,Th40;
    end;
  end;
  for p st p in P1 holds p`2 < (GoB f)*(1,1)`2
  proof
    let p;
    assume p in P1;
    then ex q st p = q & q`2 < S-bound L~f;
    hence thesis by JORDAN5D:38;
  end;
  then P1 misses L~f by GOBOARD8:23;
  then P1 \/ P2 misses L~f by A3,XBOOLE_1:70;
  then LeftComp SpStSeq L~f misses L~f by A29,A23,XBOOLE_1:70;
  then
A31: LeftComp SpStSeq L~f c= (L~f)` by SUBSET_1:23;
  LeftComp f is_a_component_of (L~f)` by GOBOARD9:def 1;
  hence thesis by A26,A20,A31,GOBOARD9:4;
end;
