reserve n,n1,m,m1,k for Nat;
reserve x,X,X1 for set;
reserve g,g1,g2,t,x0,x1,x2 for Complex;
reserve s1,s2,q1,seq,seq1,seq2,seq3 for Complex_Sequence;
reserve Y for Subset of COMPLEX;
reserve f,f1,f2,h,h1,h2 for PartFunc of COMPLEX,COMPLEX;
reserve p,r,s for Real;
reserve Ns,Nseq for increasing sequence of NAT;

theorem
  x0 in dom f implies f is_continuous_on {x0}
proof
  assume
A1: x0 in dom f;
  thus {x0} c= dom f
  by A1,TARSKI:def 1;
  let t such that
A2: t in {x0};
  thus f|{x0} is_continuous_in t
  proof
    t in dom f by A1,A2,TARSKI:def 1;
    then t in dom f /\ {x0} by A2,XBOOLE_0:def 4;
    hence t in dom (f|{x0}) by RELAT_1:61;
    let s1;
    assume that
A3: rng s1 c= dom(f|{x0}) and
    s1 is convergent and
    lim s1=t;
A4: dom f /\ {x0} c= {x0} by XBOOLE_1:17;
    rng s1 c= dom f /\ {x0} by A3,RELAT_1:61;
    then
A5: rng s1 c= {x0} by A4;
A6: now
      let n;
      s1.n in rng s1 by VALUED_0:28;
      hence s1.n = x0 by A5,TARSKI:def 1;
    end;
A7: t=x0 by A2,TARSKI:def 1;
A8: now
      let r such that
A9:   0<r;
       reconsider n=0 as Nat;
      take n;
      let m such that
      n<=m;
A10:    m in NAT by ORDINAL1:def 12;
      |.((f|{x0})/*s1).m - (f|{x0})/.t.| = |.(f|{x0})/.(s1.m) - (f|{x0})
      /.x0.| by A7,A3,FUNCT_2:109,A10
        .= |.(f|{x0})/.x0 - (f|{x0})/.x0.| by A6
        .= 0 by COMPLEX1:44;
      hence |.((f|{x0})/*s1).m - (f|{x0})/.t.| < r by A9;
    end;
    hence (f|{x0})/*s1 is convergent;
    hence thesis by A8,COMSEQ_2:def 6;
  end;
end;
