
theorem Th42:
  for C1, C2 being Coherence_Space for a being finite Element of
  C1, y being set st y in union C2 ex f being U-stable Function of C1, C2 st
  Trace f = {[a,y]}
proof
  let C1, C2 be Coherence_Space;
  let a be finite Element of C1, y be set;
  assume
A1: y in union C2;
  then [a,y] in [:C1, union C2:] by ZFMISC_1:87;
  then reconsider X = {[a,y]} as Subset of [:C1, union C2:] by ZFMISC_1:31;
A2: now
    let a1,b be Element of C1;
    assume a1 \/ b in C1;
    let y1,y2 be object;
    assume that
A3: [a1,y1] in X and
A4: [b,y2] in X;
    [b,y2] = [a,y] by A4,TARSKI:def 1;
    then
A5: y2 = y by XTUPLE_0:1;
    [a1,y1] = [a,y] by A3,TARSKI:def 1;
    then y1 = y by XTUPLE_0:1;
    then {y1,y2} = {y} by A5,ENUMSET1:29;
    hence {y1,y2} in C2 by A1,COH_SP:4;
  end;
A6: now
    let a1,b be Element of C1;
    assume a1 \/ b in C1;
    let y1 be object;
    assume [a1,y1] in X & [b,y1] in X;
    then [a1,y1] = [a,y] & [b,y1] = [a,y] by TARSKI:def 1;
    hence a1 = b by XTUPLE_0:1;
  end;
  now
    let x be set;
    assume x in X;
    then x = [a,y] by TARSKI:def 1;
    hence x`1 is finite;
  end;
  hence thesis by A2,A6,Th38;
end;
