
theorem
{f where f is Function of REAL,REAL, a,b,c,d is Real:
 for x be Real holds f.x= max(0,min(1, c*sin(a*x+b)+d))}
c= {f where f,g is Function of REAL,REAL :
    for x be Real holds f.x= max(0,min(1, g.x))}
proof
 let g be object;
 assume g in {f where f is Function of REAL,REAL, a,b,c,d is Real:
 for x be Real holds f.x= max(0,min(1, c*sin(a*x+b)+d))};
 then
 consider f be Function of REAL,REAL, a,b,c,d be Real such that
 A1:f=g and
 A2:for x be Real holds f.x= max(0,min(1, c*sin(a*x+b)+d));
 ex g being Function of REAL,REAL st
 for x be Real holds g.x= c*sin(a*x+b)+d
 proof
  deffunc H1(Element of REAL) = In(c*sin(a*$1+b)+d,REAL);
  ex  f being Function of REAL,REAL st
   for x being  Element of REAL holds
  f.x = H1(x) from FUNCT_2:sch 4;
  then
  consider f being Function of REAL,REAL such that
  A1: for x being  Element of REAL holds
  f.x = H1(x);
  take f;
  for x be Real holds f.x= c*sin(a*x+b)+d
  proof
   let x be Real;
   reconsider x as Element of REAL by XREAL_0:def 1;
   f.x = H1(x) by A1;
   hence thesis;
  end;
  hence thesis;
 end; then
 consider g being Function of REAL,REAL such that
 A4:for x be Real holds g.x= c*sin(a*x+b)+d;
 for x be Real holds f.x= max(0,min(1, g.x))
 proof
  let x be Real;
  f.x = max(0,min(1, c*sin(a*x+b)+d)) by A2
     .= max(0,min(1, g.x)) by A4;
  hence thesis;
 end;
 hence thesis by A1;
end;
