reserve n for Nat,
  i,j for Nat,
  r,s,r1,s1,r2,s2,r9,s9 for Real,
  p,q for Point of TOP-REAL 2,
  G for Go-board,
  x,y for set,
  v for Point of Euclid 2;

theorem Th42:
  1 <= i & i < len G & 1 <= j & j < width G implies LSeg(1/2*(G*(i
,j)+G*(i+1,j+1)),1/2*(G*(i+1,j)+G*(i+1,j+1))) c= Int cell(G,i,j) \/ { 1/2*(G*(i
  +1,j)+G*(i+1,j+1)) }
proof
  assume that
A1: 1 <= i and
A2: i < len G and
A3: 1 <= j and
A4: j < width G;
  let x be object;
  assume
A5: x in LSeg(1/2*(G*(i,j)+G*(i+1,j+1)),1/2*(G*(i+1,j)+G*(i+1,j+1)));
  then reconsider p = x as Point of TOP-REAL 2;
  consider r such that
A6: p = (1-r)*(1/2*(G*(i,j)+G*(i+1,j+1)))+r*(1/2*(G*(i+1,j)+G*(i+1,j+1)) ) and
A7: 0<=r and
A8: r<=1 by A5;
  now
    per cases by A8,XXREAL_0:1;
    case
      r = 1;
      then p = 0.TOP-REAL 2 + 1*(1/2*(G*(i+1,j)+G*(i+1,j+1))) by A6,RLVECT_1:10

        .= 1*(1/2*(G*(i+1,j)+G*(i+1,j+1))) by RLVECT_1:4
        .= 1/2*(G*(i+1,j)+G*(i+1,j+1)) by RLVECT_1:def 8;
      hence p in { 1/2*(G*(i+1,j)+G*(i+1,j+1)) } by TARSKI:def 1;
    end;
    case
A9:   r < 1;
      set r3 = (1-r)*(1/2), s3 = r*(1/2);
      set r1 = G*(i,1)`1, r2 = G*(i+1,1)`1, s1 = G*(1,j)`2, s2 = G*(1,j+1)`2;
A10:  r3*(r1+r1)+s3*(r1+r1) = r1;
      0 <> width G by MATRIX_0:def 10;
      then
A11:  1 <= width G by NAT_1:14;
A12:  i+1 <= len G by A2,NAT_1:13;
      i < i+1 by XREAL_1:29;
      then
A13:  r1 < r2 by A1,A12,A11,GOBOARD5:3;
      then
A14:  r1+r1 < r1+r2 by XREAL_1:6;
      r1+r2 < r2+r2 by A13,XREAL_1:6;
      then r1+r1 < r2+r2 by A14,XXREAL_0:2;
      then
A15:  s3*(r1+r1) <= s3*(r2+r2) by A7,XREAL_1:64;
      1 - r > 0 by A9,XREAL_1:50;
      then
A16:  r3 > (1/2)*0 by XREAL_1:68;
      then r3*(r1+r1) < r3*(r1+r2) by A14,XREAL_1:68;
      then
A17:  r1 < r3*(r1+r2)+s3*(r2+r2) by A15,A10,XREAL_1:8;
      0 <> len G by MATRIX_0:def 10;
      then
A18:  1 <= len G by NAT_1:14;
A19:  1 <= j+1 by A3,NAT_1:13;
A20:  Int cell(G,i,j) = { |[r9,s9]| : r1 < r9 & r9 < r2 & s1 < s9 & s9 <
      s2 } by A1,A2,A3,A4,Th26;
A21:  r3*(s2+s2)+s3*(s2+s2) = s2;
A22:  G*(i,j) = |[G*(i,j)`1,G*(i,j)`2]| by EUCLID:53
        .= |[r1,G*(i,j)`2]| by A1,A2,A3,A4,GOBOARD5:2
        .= |[r1,s1]| by A1,A2,A3,A4,GOBOARD5:1;
A23:  r3*(s1+s1)+s3*(s1+s1) = s1;
A24:  1 <= i+1 by A1,NAT_1:13;
A25:  G*(i+1,j) = |[G*(i+1,j)`1,G*(i+1,j)`2]| by EUCLID:53
        .= |[r2,G*(i+1,j)`2]| by A3,A4,A24,A12,GOBOARD5:2
        .= |[r2,s1]| by A3,A4,A24,A12,GOBOARD5:1;
A26:  r3*(r2+r2)+s3*(r2+r2) = r2;
      r1+r2 < r2+r2 by A13,XREAL_1:6;
      then r3*(r1+r2) < r3*(r2+r2) by A16,XREAL_1:68;
      then
A27:  r3*(r1+r2)+s3*(r2+r2) < r2 by A26,XREAL_1:8;
A28:  j+1 <= width G by A4,NAT_1:13;
A29:  G*(i+1,j+1) = |[G*(i+1,j+1)`1,G*(i+1,j+1)`2]| by EUCLID:53
        .= |[r2,G*(i+1,j+1)`2]| by A19,A28,A24,A12,GOBOARD5:2
        .= |[r2,s2]| by A19,A28,A24,A12,GOBOARD5:1;
      j < j+1 by XREAL_1:29;
      then
A30:  s1 < s2 by A3,A28,A18,GOBOARD5:4;
      then
A31:  s1+s1 < s1+s2 by XREAL_1:6;
      then
A32:  s3*(s1+s1) <= s3*(s1+s2) by A7,XREAL_1:64;
      r3*(s1+s1) < r3*(s1+s2) by A16,A31,XREAL_1:68;
      then
A33:  s1 < r3*(s1+s2)+s3*(s1+s2) by A32,A23,XREAL_1:8;
A34:  s1+s2 < s2+s2 by A30,XREAL_1:6;
      then
A35:  s3*(s1+s2) <= s3*(s2+s2) by A7,XREAL_1:64;
      r3*(s1+s2) < r3*(s2+s2) by A16,A34,XREAL_1:68;
      then
A36:  r3*(s1+s2)+s3*(s1+s2) < s2 by A35,A21,XREAL_1:8;
      p = r3*(G*(i,j)+G*(i+1,j+1))+r*(1/2*(G*(i+1,j)+G*(i+1,j+1))) by A6,
RLVECT_1:def 7
        .= r3*(G*(i,j)+G*(i+1,j+1))+s3*(G*(i+1,j)+G*(i+1,j+1)) by
RLVECT_1:def 7
        .= r3*|[r1+r2,s1+s2]|+s3*(G*(i+1,j)+G*(i+1,j+1)) by A22,A29,EUCLID:56
        .= r3*|[r1+r2,s1+s2]|+s3*|[r2+r2,s1+s2]| by A29,A25,EUCLID:56
        .= |[r3*(r1+r2),r3*(s1+s2)]|+s3*|[r2+r2,s1+s2]| by EUCLID:58
        .= |[r3*(r1+r2),r3*(s1+s2)]|+|[s3*(r2+r2),s3*(s1+s2)]| by EUCLID:58
        .= |[r3*(r1+r2)+s3*(r2+r2),r3*(s1+s2)+s3*(s1+s2)]| by EUCLID:56;
      hence p in Int cell(G,i,j) by A17,A27,A33,A36,A20;
    end;
  end;
  hence thesis by XBOOLE_0:def 3;
end;
