reserve r,x,x0,a,b for Real;
reserve n,m for Element of NAT;
reserve A for non empty closed_interval Subset of REAL;
reserve Z for open Subset of REAL;
reserve f, f1, f2, f3 for PartFunc of REAL, REAL;

theorem
  A c= Z & (for x st x in Z holds (1+cos.x)<>0 & (1-cos.x)<>0 & f.x = 1/
  (1+cos.x)) & dom (-cot+cosec)=Z & Z = dom f & f|A is continuous implies
  integral(f,A) = (-cot+cosec).(upper_bound A)-(-cot+cosec).(lower_bound A)
proof
  assume that
A1: A c= Z and
A2: for x st x in Z holds (1+cos.x)<>0 & (1-cos.x)<>0 & f.x = 1/(1+cos. x) and
A3: dom (-cot+cosec)=Z and
A4: Z = dom f and
A5: f|A is continuous;
A6: f is_integrable_on A by A1,A4,A5,INTEGRA5:11;
A7: for x st x in Z holds (1+cos.x)<>0 & (1-cos.x)<>0 by A2;
  then
A8: (-cot+cosec) is_differentiable_on Z by A3,Th41;
A9: for x being Element of REAL
st x in dom ((-cot+cosec)`|Z) holds ((-cot+cosec)`|Z).x = f.x
  proof
    let x be Element of REAL;
    assume x in dom ((-cot+cosec)`|Z);
    then
A10: x in Z by A8,FDIFF_1:def 7;
    then ((-cot+cosec)`|Z).x = 1/(1+cos.x) by A3,A7,Th41
      .= f.x by A2,A10;
    hence thesis;
  end;
  dom ((-cot+cosec)`|Z) = dom f by A4,A8,FDIFF_1:def 7;
  then ((-cot+cosec)`|Z) = f by A9,PARTFUN1:5;
  hence thesis by A1,A4,A5,A6,A8,INTEGRA5:10,13;
end;
