reserve X for set;
reserve n,i for Element of NAT;
reserve a,b,c,d,e,r,x0 for Real;
reserve A for non empty closed_interval Subset of REAL;
reserve f,g,h for PartFunc of REAL,REAL n;
reserve E for Element of REAL n;

theorem Th42:
  for f be Function of A,REAL n, g be Function of A,REAL-NS n
  st f=g & f is bounded & f is integrable
  holds g is integrable & integral(f) = integral(g)
  proof
    let f be Function of A,REAL n,
    g be Function of A,REAL-NS n;
    assume A1: f=g & f is bounded & f is integrable;
    then
A2: g is integrable by Th41;
A3: for T be DivSequence of A, S be middle_volume_Sequence of f,T
    st delta(T) is convergent & lim delta(T)=0 holds
    middle_sum(f,S) is convergent & lim (middle_sum(f,S))=integral(f)
    by A1,INTEGR15:11;
    reconsider I0 = integral(f) as Point of REAL-NS n by REAL_NS1:def 4;
    integral(f)=I0; then
    for T be DivSequence of A, S0 be middle_volume_Sequence of g,T
    st delta(T) is convergent & lim delta(T)=0 holds
    middle_sum(g,S0) is convergent & lim (middle_sum(g,S0))=I0 by A3,A1,Th40;
    hence thesis by A2,INTEGR18:def 6;
  end;
