reserve n for Nat;

theorem
  for C be compact non vertical non horizontal non empty Subset of
  TOP-REAL 2 ex i be Nat st 1 <= i & i+1 <= len Gauge(C,n) & W-min C
  in cell(Gauge(C,n),1,i) & W-min C <> Gauge(C,n)*(2,i)
proof
  let C be compact non vertical non horizontal non empty Subset of TOP-REAL 2;
  set G = Gauge(C,n);
  defpred P[Nat] means 1 <= $1 & $1 < len G & G*(2,$1)`2 < (W-min C)`2;
A1: for k be Nat st P[k] holds k <= len G;
A2: len G = width G by JORDAN8:def 1;
  (SW-corner C)`2 <= (W-min C)`2 by PSCOMP_1:30;
  then
A3: S-bound C <= (W-min C)`2 by EUCLID:52;
A4: len G >= 4 by JORDAN8:10;
  then
A5: 1 < len G by XXREAL_0:2;
A6: 2 <= len G by A4,XXREAL_0:2;
  then G*(2,2)`2 = S-bound C by JORDAN8:13;
  then G*(2,1)`2 < S-bound C by A2,A6,GOBOARD5:4;
  then G*(2,1)`2 < (W-min C)`2 by A3,XXREAL_0:2;
  then
A7: ex k be Nat st P[k] by A5;
  ex i being Nat st P[i] & for n be Nat st P[n] holds n <= i from NAT_1:
  sch 6(A1,A7);
  then consider i being Nat such that
A8: 1 <= i and
A9: i < len G and
A10: G*(2,i)`2 < (W-min C)`2 and
A11: for n be Nat st P[n] holds n <= i;
  reconsider i as Nat;
A12: (W-min C)`1 = W-bound C by EUCLID:52;
  then
A13: G*(2,i)`1 = (W-min C)`1 by A8,A9,JORDAN8:11;
A14: i+1 <= len G by A9,NAT_1:13;
  then
A15: (W-min C)`1 = G*(2,i+1)`1 by A12,JORDAN8:11,NAT_1:12;
A16: i < i+1 by NAT_1:13;
A17: 1 <= i+1 by NAT_1:12;
  now
    assume i+1 = len G;
    then len G-'1 = i by NAT_D:34;
    then
A18: G*(2,i)`2 = N-bound C by A6,JORDAN8:14;
    (NW-corner C)`2 >= (W-min C)`2 by PSCOMP_1:30;
    hence contradiction by A10,A18,EUCLID:52;
  end;
  then i+1 < len G by A14,XXREAL_0:1;
  then (W-min C)`2 <= G*(2,i+1)`2 by A11,A17,A16;
  then
A19: W-min C in LSeg(G*(2,i),G*(2,i+1)) by A10,A13,A15,GOBOARD7:7;
  take i;
  thus 1 <= i & i+1 <= len G by A8,A9,NAT_1:13;
  len G = width G by JORDAN8:def 1;
  then LSeg(G*(1+1,i),G*(1+1,i+1)) c= cell(G,1,i) by A5,A8,A9,GOBOARD5:18;
  hence W-min C in cell(G,1,i) by A19;
  thus thesis by A10;
end;
