reserve f, g, h for Function;
reserve x, y, z, u, X for set,
  A for non empty set,
  n for Element of NAT,
  f for Function of X, X;
reserve f for c=-monotone Function of bool X, bool X,
  S for Subset of X;
reserve X, Y for non empty set,
  f for Function of X, Y,
  g for Function of Y, X;
reserve L for Lattice,
  f for Function of the carrier of L, the carrier of L,
  x for Element of L,
  O, O1, O2, O3, O4 for Ordinal,
  T for Sequence;
reserve L for complete Lattice,
  f for monotone UnOp of L,
  a, b for Element of L;

theorem Th42:
  gfp f is_a_fixpoint_of f & ex O st card O c= card the carrier of
  L & (f, O)-.Top L = gfp f
proof
  reconsider je = Top L as Element of L;
A1: f.je [= Top L by LATTICES:19;
  then consider O such that
A2: card O c= card the carrier of L and
A3: (f, O)-.Top L is_a_fixpoint_of f by Th31;
  card the carrier of L in nextcard the carrier of L by CARD_1:def 3;
  then card O in nextcard the carrier of L by A2,ORDINAL1:12;
  then O in nextcard the carrier of L by CARD_3:44;
  then
A4: O c= nextcard the carrier of L by ORDINAL1:def 2;
  hence gfp f is_a_fixpoint_of f by A1,A3,Th29;
  take O;
  thus card O c= card the carrier of L by A2;
  thus thesis by A1,A3,A4,Th29;
end;
