reserve X for non empty set,
  S for SigmaField of X,
  M for sigma_Measure of S,
  E for Element of S,
  F,G for Functional_Sequence of X,ExtREAL,
  I for ExtREAL_sequence,
  f,g for PartFunc of X,ExtREAL,
  seq, seq1, seq2 for ExtREAL_sequence,
  p for ExtReal,
  n,m for Nat,
  x for Element of X,
  z,D for set;

theorem Th42:
  F is additive & F is with_the_same_dom & G is additive & G is
with_the_same_dom & x in dom(F.0) /\ dom(G.0) & (for k be Nat, y be Element of
X st y in dom(F.0) /\ dom(G.0) holds (F.k).y <= (G.k).y) implies ((Partial_Sums
  F).n).x <= ((Partial_Sums G).n).x
proof
  assume that
A1: F is additive and
A2: F is with_the_same_dom and
A3: G is additive and
A4: G is with_the_same_dom and
A5: x in dom(F.0) /\ dom(G.0) and
A6: for k be Nat, y be Element of X st y in dom(F.0) /\ dom(G.0) holds (
  F.k).y <= (G.k).y;
  set PG = Partial_Sums G;
  set PF = Partial_Sums F;
  defpred P[Nat] means (PF.$1).x <= (PG.$1).x;
A7: for k being Nat st P[k] holds P[k+1]
  proof
    let k be Nat;
    assume
A8: P[k];
    dom(PF.(k+1)) = dom(F.0) by A1,A2,Th29;
    then
A9: x in dom(PF.(k+1)) by A5,XBOOLE_0:def 4;
    dom(PG.(k+1)) = dom(G.0) by A3,A4,Th29;
    then
A10: x in dom(PG.(k+1)) by A5,XBOOLE_0:def 4;
    PG.(k+1) = PG.k + G.(k+1) by Def4;
    then
A11: (PG.(k+1)).x = (PG.k).x + (G.(k+1)).x by A10,MESFUNC1:def 3;
    PF.(k+1) = PF.k + F.(k+1) by Def4;
    then
A12: (PF.(k+1)).x = (PF.k).x + (F.(k+1)).x by A9,MESFUNC1:def 3;
    (F.(k+1)).x <= (G.(k+1)).x by A5,A6;
    hence thesis by A8,A12,A11,XXREAL_3:36;
  end;
A13: (PG.0) = G.0 by Def4;
  (PF.0) = F.0 by Def4;
  then
A14: P[ 0 ] by A5,A6,A13;
  for k being Nat holds P[k] from NAT_1:sch 2(A14,A7);
  hence thesis;
end;
