reserve n,m,i,k for Element of NAT;
reserve x,X,X1 for set;
reserve r,p for Real;
reserve s,x0,x1,x2 for Real;
reserve f,f1,f2 for PartFunc of REAL,REAL n;
reserve h for PartFunc of REAL,REAL-NS n;
reserve W for non empty set;

theorem Th42:
  for x0 be Element of REAL n st 1 <= i & i <= n
  holds proj(i,n) is_continuous_in x0
proof
let x0 be Element of REAL n;
assume A1: 1 <=i & i <= n;
A2:dom proj(i,n) = REAL n by FUNCT_2:def 1;
reconsider prg=proj(i,n) as PartFunc of REAL-NS n,REAL
  by REAL_NS1:def 4;
reconsider px0 = x0 as Element of REAL-NS n
  by REAL_NS1:def 4;
now let r be Real;
   assume A3: 0<r;
   take s = r;
   thus 0<s by A3;
      now let px1 be Element of REAL-NS n;
      assume A4: px1 in dom prg & ||.px1-px0.|| < r;
        reconsider x1=px1 as Element of REAL n by REAL_NS1:def 4;
A5:    ||.px1-px0.|| = |.x1-x0.| by REAL_NS1:1,5;
       proj(i,n)/.(x1-x0) =proj(i,n)/.x1-proj(i,n)/.x0 by A1,PDIFF_8:12;
       then |. proj(i,n)/.x1-proj(i,n)/.x0.| <= |. x1-x0 .|
        by A1,PDIFF_8:5;
     hence |. proj(i,n)/.px1-proj(i,n)/.px0.| < r by A4,A5,XXREAL_0:2;
    end;
  hence for px1 be Element of REAL-NS n st px1 in dom prg
     & ||.px1-px0.|| < s holds |. proj(i,n)/.px1-proj(i,n)/.px0 .|<r;
 end;
 then prg is_continuous_in px0 by A2,NFCONT_1:8;
 hence thesis;
end;
