reserve A,A1,A2,B,C,D for Ordinal,
  X,Y for set,
  x,y,a,b,c for object,
  L,L1,L2,L3 for Sequence,
  f for Function;
reserve fi,psi for Ordinal-Sequence;

theorem
  A c= B implies C*^A c= C*^B
proof
  assume
A1: A c= B;
  now
    defpred P[Ordinal] means $1*^A c= $1*^B;
    assume
A2: B <> 0;
A3: for C st for D st D in C holds P[D] holds P[C]
    proof
      let C such that
A4:   for D st D in C holds D*^A c= D*^B;
A5:   now
        given D such that
A6:     C = succ D;
        D*^A c= D*^B by A4,A6,ORDINAL1:6;
        then
A7:     D*^A +^ A c= D*^B +^ A by Th34;
A8:     C*^A = D*^A +^ A & C*^B = D*^B +^ B by A6,Th36;
        D*^B +^ A c= D*^B +^ B by A1,Th33;
        hence thesis by A7,A8,XBOOLE_1:1;
      end;
A9:   now
        deffunc F(Ordinal) = $1*^A;
        assume that
A10:    C <> 0 and
A11:    for D holds C <> succ D;
        consider fi such that
A12:    dom fi = C & for D st D in C holds fi.D = F(D) from OSLambda;
        now
          let D;
          assume D in rng fi;
          then consider x being object such that
A13:      x in dom fi and
A14:      D = fi.x by FUNCT_1:def 3;
          reconsider x as Ordinal by A13;
A15:      x*^B in C*^B by A2,A12,A13,Th40;
          D = x*^A & x*^A c= x*^B by A4,A12,A13,A14;
          hence D in C*^B by A15,ORDINAL1:12;
        end;
        then
A16:    sup rng fi c= C*^B by Th20;
        C is limit_ordinal by A11,ORDINAL1:29;
        then
A17:    C*^A = union sup fi by A10,A12,Th37
          .= union sup rng fi;
        union sup rng fi c= sup rng fi by Th5;
        hence thesis by A17,A16,XBOOLE_1:1;
      end;
      now
        assume C = 0;
        then C*^A = 0 by Th35;
        hence thesis;
      end;
      hence thesis by A5,A9;
    end;
    for C holds P[C] from ORDINAL1:sch 2(A3);
    hence thesis;
  end;
  hence thesis by A1;
end;
