reserve m,n for non zero Element of NAT;
reserve i,j,k for Element of NAT;
reserve Z for set;

theorem Th42:
for f be PartFunc of REAL m,REAL,
    g be PartFunc of REAL-NS m,REAL
 st f = g holds Z c= dom f & f is_continuous_on Z iff g is_continuous_on Z
proof
   let f be PartFunc of REAL m,REAL,
       g be PartFunc of REAL-NS m,REAL;
   assume A1: f = g;
   hereby
     assume
A2:  Z c= dom f;
     assume A3: f is_continuous_on Z;
    now let x0 be Point of REAL-NS m;
     assume A4: x0 in Z;
     reconsider y0=x0 as Element of REAL m by REAL_NS1:def 4;
     f|Z is_continuous_in y0 by A4,A3;
     hence g|Z is_continuous_in x0 by A1,NFCONT_4:21;
    end;
    hence g is_continuous_on Z by A1,A2,NFCONT_1:def 8;
   end;
   assume A5: g is_continuous_on Z;
   hence Z c= dom f by A1,NFCONT_1:def 8;
   let x0 be Element of REAL m;
   assume A6: x0 in Z;
   reconsider y0=x0 as Point of  REAL-NS m by REAL_NS1:def 4;
   g|Z is_continuous_in y0 by A6,A5,NFCONT_1:def 8;
   hence f|Z is_continuous_in x0 by A1,NFCONT_4:21;
 end;
