reserve x,y,X for set,
        r for Real,
        n,k for Nat;
reserve RLS for non empty RLSStruct,
        Kr,K1r,K2r for SimplicialComplexStr of RLS,
        V for RealLinearSpace,
        Kv for non void SimplicialComplex of V;
reserve Ks for simplex-join-closed SimplicialComplex of V,
        As,Bs for Subset of Ks,
        Ka for non void affinely-independent SimplicialComplex of V,
        Kas for non void affinely-independent simplex-join-closed
                 SimplicialComplex of V,
        K for non void affinely-independent simplex-join-closed total
                 SimplicialComplex of V;
reserve Aff for finite affinely-independent Subset of V,
        Af,Bf for finite Subset of V,
        B for Subset of V,
        S,T for finite Subset-Family of V,
        Sf for c=-linear finite finite-membered Subset-Family of V,
        Sk,Tk for finite simplex-like Subset-Family of K,
        Ak for Simplex of K;

theorem Th42:
  Sk is c=-linear with_non-empty_elements & card Sk = card union Sk &
        union Sk c= Ak & card Ak = card Sk+1
implies
   {S1 where S1 is Simplex of card Sk,BCS K:
        (center_of_mass V).:Sk c= S1 & conv @S1 c= conv @Ak}
   = {(center_of_mass V).:Sk \/(center_of_mass V).:{Ak}}
 proof
  set B=center_of_mass V;
  assume that
   A1: Sk is c=-linear with_non-empty_elements and
   A2: card Sk=card union Sk and
   A3: union Sk c=Ak and
   A4: card Ak=card Sk+1;
  card(Ak\union Sk)=card Sk+1-card Sk by A2,A3,A4,CARD_2:44
   .=1;
  then consider v be object such that
   A5: Ak\union Sk={v} by CARD_2:42;
  reconsider Ak1=@Ak as affinely-independent finite Subset of V;
  set C=Complex_of{Ak1};
  reconsider c =card Ak as ExtReal;
  A6: degree C=c-1 by SIMPLEX0:26
   .=card Ak+-1 by XXREAL_3:def 2
   .=card Sk by A4;
  reconsider Sk1=@Sk as c=-linear finite finite-membered Subset-Family of V by
A1;
  set XX={W where W is Simplex of card Sk,BCS C:B.:Sk c=W};
  set YY={W where W is Simplex of card Sk,BCS K:B.:Sk c=W & conv@W c=conv@Ak};
  [#]K=the carrier of V by SIMPLEX0:def 10;
  then |.K.|c=[#]K;
  then A7: subdivision(B,K)=BCS K by Def5;
  A8: C is SubSimplicialComplex of K by Th3;
  then the topology of C c=the topology of K by SIMPLEX0:def 13;
  then A9: |.C.|c=|.K.| by Th4;
  A10: [#]C=[#]V;
  then A11: degree C=degree BCS C by A9,Th31;
  subdivision(B,C)=BCS C by A9,A10,Def5;
  then BCS C is SubSimplicialComplex of BCS K by A7,A8,SIMPLEX0:58;
  then A12: degree BCS C<=degree BCS K by SIMPLEX0:32;
  A13: XX c=YY
  proof
   let x be object;
   assume x in XX;
   then consider W be Simplex of card Sk,BCS C such that
    A14: x=W & B.:Sk1 c=W;
   W=@W;
   then reconsider w=W as Simplex of BCS K by Th40;
   card W=degree BCS C+1 by A6,A11,SIMPLEX0:def 18;
   then A15: w is Simplex of card Sk,BCS K by A6,A11,A12,SIMPLEX0:def 18;
   conv@W c=conv@Ak & @w=w by Th40;
   hence thesis by A14,A15;
  end;
  A16: [#]subdivision(B,C)=[#]C by SIMPLEX0:def 20;
  A17: YY c=XX
  proof
   let x be object;
   reconsider c1=card Sk as ExtReal;

   assume x in YY;
   then consider W be Simplex of card Sk,BCS K such that
    A18: W=x & B.:Sk c=W and
    A19: conv@W c=conv@Ak;
   reconsider w=@W as Subset of BCS C by A9,A16,Def5;
   reconsider cW=card W as ExtReal;
   card W=c1+1 by A6,A11,A12,SIMPLEX0:def 18
    .=card Sk+1 by XXREAL_3:def 2;
   then card Sk=card W+-1;
   then A20: card Sk=cW-1 by XXREAL_3:def 2;
   w is simplex-like by A19,Th40;
   then w is Simplex of card Sk,BCS C by A20,SIMPLEX0:48;
   hence thesis by A18;
  end;
  v in {v} by TARSKI:def 1;
  then A21: v in Ak1 & not v in union Sk by A5,XBOOLE_0:def 5;
  Ak=Ak\/union Sk by A3,XBOOLE_1:12
   .={v}\/union Sk1 by A5,XBOOLE_1:39;
  then XX={B.:Sk1\/B.:{Ak}} by A1,A2,A21,Th38;
  hence thesis by A13,A17;
 end;
