reserve x,x0, r,r1,r2 for Real,
      th for Real,

  rr for set,

  rseq for Real_Sequence;

theorem Th42:
  rng(sec | [.3/4*PI,PI.]) = [.-sqrt 2,-1.]
proof
  now
    let y be object;
    thus y in [.-sqrt 2,-1.] implies
ex x be object st x in dom (sec | [.3/4*PI,
    PI.]) & y = (sec | [.3/4*PI,PI.]).x
    proof
      [.3/4*PI,PI.] c= ].PI/2,PI.] by Lm6,XXREAL_2:def 12;
      then
A1:   sec|[.3/4*PI,PI.] is continuous by Th38,FCONT_1:16;
      assume
A2:   y in [.-sqrt 2,-1.];
      then reconsider y1=y as Real;
A3:   3/4*PI <= PI by Lm6,XXREAL_1:2;
      y1 in [.sec.(3/4*PI),sec.PI.] \/ [.sec.PI,sec.(3/4*PI).] by A2,Th31,
XBOOLE_0:def 3;
      then consider x be Real such that
A4:   x in [.3/4*PI,PI.] & y1 = sec.x by A3,A1,Lm14,Th2,FCONT_2:15,XBOOLE_1:1;
      take x;
      thus thesis by A4,Lm30,FUNCT_1:49;
    end;
    thus (ex x be object
st x in dom (sec | [.3/4*PI,PI.]) & y = (sec | [.3/4*PI,
    PI.]).x) implies y in [.-sqrt 2,-1.]
    proof
      given x be object such that
A5:   x in dom (sec | [.3/4*PI,PI.]) and
A6:   y = (sec | [.3/4*PI,PI.]).x;
      reconsider x1=x as Real by A5;
      y = sec.x1 by A5,A6,Lm30,FUNCT_1:49;
      hence thesis by A5,Lm30,Th34;
    end;
  end;
  hence thesis by FUNCT_1:def 3;
end;
