
theorem
  for C1, C2 being Coherence_Space for a being Element of C1, y being
  set for f being U-stable Function of C1, C2 st Trace f = {[a,y]} for b being
Element of C1 holds (a c= b implies f.b = {y}) & (not a c= b implies f.b = {})
proof
  let C1, C2 be Coherence_Space;
  let a be Element of C1, y be set;
  let f be U-stable Function of C1, C2;
  assume
A1: Trace f = {[a,y]};
  let b be Element of C1;
A2: [a,y] in Trace f by A1,TARSKI:def 1;
  hereby
A3: f.b c= {y}
    proof
      let x be object;
      assume x in f.b;
      then consider c being Element of C1 such that
A4:   [c,x] in Trace f and
      c c= b by Th40;
      [c,x] = [a,y] by A1,A4,TARSKI:def 1;
      then x = y by XTUPLE_0:1;
      hence thesis by TARSKI:def 1;
    end;
    assume a c= b;
    then y in f.b by A2,Th40;
    then {y} c= f.b by ZFMISC_1:31;
    hence f.b = {y} by A3;
  end;
  assume that
A5: not a c= b and
A6: f.b <> {};
  reconsider B = f.b as non empty set by A6;
  set z = the Element of B;
  consider c being Element of C1 such that
A7: [c,z] in Trace f and
A8: c c= b by Th40;
  [c,z] = [a,y] by A1,A7,TARSKI:def 1;
  hence thesis by A5,A8,XTUPLE_0:1;
end;
