reserve i,n,m for Nat,
  x,y,X,Y for set,
  r,s for Real;

theorem Th42:
  for M be symmetric triangle Reflexive non empty MetrStruct st M
is complete for a be Point of M st ex b be Point of M st dist(a,b)<>0 for X be
  infinite set holds WellSpace(a,X) is complete &
  ex S be non-empty pointwise_bounded
  SetSequence of WellSpace(a,X) st S is closed & S is non-ascending & meet S is
  empty
proof
  let M be symmetric triangle Reflexive non empty MetrStruct such that
A1: M is complete;
  let a be Point of M;
  assume ex b be Point of M st dist(a,b) <> 0;
  then consider b be Point of M such that
A2: dist(a,b)<>0;
  let X be infinite set;
  set W=WellSpace(a,X);
  thus W is complete by A1,Th41;
  set TW=TopSpaceMetr W;
  consider f being sequence of  X such that
A3: f is one-to-one by DICKSON:3;
  defpred p[object,object] means $2=[f.$1,b];
A4: b<>a by A2,METRIC_1:1;
A5: for x being object st x in NAT
ex y being object st y in the carrier of TW & p[x,y]
  proof
    let x be object;
    assume x in NAT;
    then x in dom f by FUNCT_2:def 1;
    then
A6: f.x in rng f by FUNCT_1:def 3;
    take [f.x,b];
    thus thesis by A4,A6,Th37;
  end;
  consider s be sequence of  the carrier of TW such that
A7: for x being object st x in NAT holds p[x,s.x] from FUNCT_2:sch 1(A5);
  deffunc P(object)={s.$1};
A8: for x being object st x in NAT holds P(x) in bool(the carrier of TW)
  proof
A9: dom s=NAT by FUNCT_2:def 1;
    let x be object;
    assume x in NAT;
    then s.x in rng s by A9,FUNCT_1:def 3;
    then P(x) is Subset of W by SUBSET_1:33;
    hence thesis;
  end;
  consider S be SetSequence of TW such that
A10: for x being object st x in NAT holds S.x=P(x) from FUNCT_2:sch 2(A8);
A11: now
    let x1,x2 be object such that
A12: x1 in NAT and
A13: x2 in NAT and
A14: S.x1 = S.x2;
A15: S.x2={s.x2} by A10,A13;
A16: s.x1=[f.x1,b] by A7,A12;
A17: s.x1 in {s.x1} by TARSKI:def 1;
A18: s.x2=[f.x2,b] by A7,A13;
    S.x1={s.x1} by A10,A12;
    then s.x1=s.x2 by A14,A15,A17,TARSKI:def 1;
    then f.x1=f.x2 by A16,A18,XTUPLE_0:1;
    hence x1 = x2 by A3,A12,A13,FUNCT_2:19;
  end;
  reconsider rngs=rng s as Subset of TW;
  set F={{x} where x is Element of TW: x in rngs};
  reconsider F as Subset-Family of TW by RELSET_2:16;
  dist(a,b)>0 by A2,METRIC_1:5;
  then
A19: 2*dist(a,b)>0 by XREAL_1:129;
A20: rng S c= F
  proof
    let x be object;
    assume x in rng S;
    then consider y being object such that
A21: y in dom S and
A22: S.y=x by FUNCT_1:def 3;
    dom s=NAT by FUNCT_2:def 1;
    then
A23: s.y in rngs by A21,FUNCT_1:def 3;
    x={s.y} by A10,A21,A22;
    hence thesis by A23;
  end;
  now
    let x be object;
    assume x in dom S;
    then S.x={s.x} by A10;
    hence S.x is non empty;
  end;
  then S is non-empty by FUNCT_1:def 9;
  then consider R be non-empty closed SetSequence of TW such that
A24: R is non-ascending and
A25: F is locally_finite & S is one-to-one implies meet R = {} and
A26: for i ex Si be Subset-Family of TW st R.i = Cl union Si & Si = {S.j
  where j is Element of NAT: j >= i} by A20,Th23;
  reconsider R9=R as non-empty SetSequence of W;
A27: now
    let x,y be Point of W such that
A28: x in rngs and
A29: y in rngs and
A30: x <> y;
    consider y1 be object such that
A31: y1 in dom s and
A32: s.y1=y by A29,FUNCT_1:def 3;
A33: y=[f.y1,b] by A7,A31,A32;
    consider x1 be object such that
A34: x1 in dom s and
A35: s.x1=x by A28,FUNCT_1:def 3;
    x=[f.x1,b] by A7,A34,A35;
    then well_dist(a,X).(x,y)=dist(b,a)+dist(a,b) by A30,A33,Def10;
    hence dist(x,y)=2*dist(a,b);
  end;
  now
    let i;
    consider Si be Subset-Family of TW such that
A36: R.i = Cl union Si and
A37: Si = {S.j where j is Element of NAT: j >= i} by A26;
    reconsider SI=union Si as Subset of W;
    now
      let x,y being Point of W such that
A38:  x in SI and
A39:  y in SI;
      consider xS be set such that
A40:  x in xS and
A41:  xS in Si by A38,TARSKI:def 4;
      consider j1 be Element of NAT such that
A42:  xS=S.j1 and
      j1 >= i by A37,A41;
A43:  S.j1={s.j1} by A10;
A44:  dom s=NAT by FUNCT_2:def 1;
      then s.j1 in rngs by FUNCT_1:def 3;
      then
A45:  x in rngs by A40,A42,A43,TARSKI:def 1;
      consider yS be set such that
A46:  y in yS and
A47:  yS in Si by A39,TARSKI:def 4;
      consider j2 be Element of NAT such that
A48:  yS=S.j2 and
      j2 >= i by A37,A47;
A49:  S.j2={s.j2} by A10;
      s.j2 in rngs by A44,FUNCT_1:def 3;
      then
A50:  y in rngs by A46,A48,A49,TARSKI:def 1;
      x=y or x<>y;
      hence dist(x,y)<=2*dist(a,b) by A19,A27,A45,A50,METRIC_1:1;
    end;
    then SI is bounded by A19;
    hence R9.i is bounded by A36,Th8;
  end;
  then reconsider R9 as non-empty pointwise_bounded SetSequence of W by Def1;
  take R9;
  thus R9 is closed & R9 is non-ascending by A24,Th7;
  for x,y be Point of W st x<>y & x in rngs & y in rngs holds dist(x,y)>=
  2*dist(a,b) by A27;
  hence thesis by A25,A19,A11,Lm7,FUNCT_2:19;
end;
