reserve x for Real,

  Z for open Subset of REAL;

theorem
  Z c= dom (sin*sec) implies sin*sec is_differentiable_on Z & for x st x
  in Z holds ((sin*sec)`|Z).x = cos.(sec.x)* sin.x/(cos.x)^2
proof
  assume
A1: Z c= dom (sin*sec);
  dom (sin*sec) c= dom sec by RELAT_1:25;
  then
A2: Z c= dom sec by A1,XBOOLE_1:1;
A3: for x st x in Z holds sin*sec is_differentiable_in x
  proof
    let x;
    assume x in Z;
    then cos.x<>0 by A2,RFUNCT_1:3;
    then
A4: sec is_differentiable_in x by FDIFF_9:1;
    sin is_differentiable_in sec.x by SIN_COS:64;
    hence thesis by A4,FDIFF_2:13;
  end;
  then
A5: sin*sec is_differentiable_on Z by A1,FDIFF_1:9;
  for x st x in Z holds ((sin*sec)`|Z).x = cos.(sec.x)* sin.x/(cos.x)^2
  proof
    let x;
A6: sin is_differentiable_in sec.x by SIN_COS:64;
    assume
A7: x in Z;
    then
A8: cos.x <>0 by A2,RFUNCT_1:3;
    then sec is_differentiable_in x by FDIFF_9:1;
    then diff(sin*sec,x) = diff(sin,sec.x)*diff(sec,x) by A6,FDIFF_2:13
      .= cos(sec.x)*diff(sec,x) by SIN_COS:64
      .= cos(sec.x)* (sin.x/(cos.x)^2) by A8,FDIFF_9:1
      .=cos.(sec.x)* sin.x/(cos.x)^2;
    hence thesis by A5,A7,FDIFF_1:def 7;
  end;
  hence thesis by A1,A3,FDIFF_1:9;
end;
