reserve x for Real;
reserve p,q for Point of TOP-REAL 2;

theorem Th43:
  Sq_Circ is Function of TOP-REAL 2,TOP-REAL 2 & rng Sq_Circ = the
  carrier of TOP-REAL 2 & for f being Function of TOP-REAL 2,TOP-REAL 2 st f=
  Sq_Circ holds f is being_homeomorphism
proof
  thus Sq_Circ is Function of TOP-REAL 2,TOP-REAL 2;
A1: for f being Function of TOP-REAL 2,TOP-REAL 2 st f=Sq_Circ holds rng
  Sq_Circ=the carrier of TOP-REAL 2 & f is being_homeomorphism
  proof
    let f be Function of TOP-REAL 2,TOP-REAL 2;
    assume
A2: f=Sq_Circ;
    reconsider g=f/" as Function of TOP-REAL 2,TOP-REAL 2;
A3: dom f=the carrier of TOP-REAL 2 by FUNCT_2:def 1;
    the carrier of TOP-REAL 2 c= rng f
    proof
      let y be object;
      assume y in the carrier of TOP-REAL 2;
      then reconsider p2=y as Point of TOP-REAL 2;
      set q=p2;
      now
        per cases;
        case
          q=0.TOP-REAL 2;
          then y=Sq_Circ.q by Def1;
          hence ex x being set st x in dom Sq_Circ & y=Sq_Circ.x by A2,A3;
        end;
        case
A4:       q<>0.TOP-REAL 2 & (q`2<=q`1 & -q`1<=q`2 or q`2>=q`1 & q`2<=- q`1);
          set px=|[q`1*sqrt(1+(q`2/q`1)^2),q`2*sqrt(1+(q`2/q`1)^2)]|;
A5:       sqrt(1+(q`2/q`1)^2)>0 by Lm1,SQUARE_1:25;
A6:       now
            assume that
A7:         px`1=0 and
A8:         px`2=0;
            q`2*sqrt(1+(q`2/q`1)^2 )=0 by A8,EUCLID:52;
            then
A9:         q`2=0 by A5,XCMPLX_1:6;
            q`1*sqrt(1+(q`2/q`1)^2)=0 by A7,EUCLID:52;
            then q`1=0 by A5,XCMPLX_1:6;
            hence contradiction by A4,A9,EUCLID:53,54;
          end;
A10:      dom Sq_Circ=the carrier of TOP-REAL 2 by FUNCT_2:def 1;
A11:      px`1 = q`1*sqrt(1+(q`2/q`1)^2) by EUCLID:52;
A12:      px`2 = q`2*sqrt(1+(q`2/q`1)^2) by EUCLID:52;
          then
A13:      px`2/px`1=q`2/q`1 by A11,A5,XCMPLX_1:91;
          then
A14:      px`2/sqrt(1+(px`2/px`1)^2)=q`2 by A12,A5,XCMPLX_1:89;
          q`2<=q`1 & -q`1<=q`2 or q`2>=q`1 & q`2*sqrt(1+(q`2/q`1)^2) <= (
          -q`1)*sqrt(1+(q`2/q`1)^2) by A4,A5,XREAL_1:64;
          then
          q`2<=q`1 & (-q`1)*sqrt(1+(q`2/q`1)^2) <= q`2*sqrt(1+(q`2/q`1)^2
          ) or px`2>=px`1 & px`2<=-px`1 by A11,A12,A5,XREAL_1:64;
          then q`2*sqrt(1+(q`2/q`1)^2) <= q`1*sqrt(1+(q`2/q`1)^2) & -px`1<=px
          `2 or px`2>=px`1 & px`2<=-px`1 by A11,A5,EUCLID:52,XREAL_1:64;
          then
A15:      Sq_Circ.px=|[px`1/sqrt(1+(px`2/px`1)^2),px`2/sqrt(1+( px`2/px`1
          )^2) ]| by A11,A12,A6,Def1,JGRAPH_2:3;
          px`1/sqrt(1+(px`2/px`1)^2)=q`1 by A11,A5,A13,XCMPLX_1:89;
          hence ex x being set st x in dom Sq_Circ & y=Sq_Circ.x by A15,A14,A10
,EUCLID:53;
        end;
        case
A16:      q<>0.TOP-REAL 2 & not(q`2<=q`1 & -q`1<=q`2 or q`2>=q`1 & q `2<=-q`1);
          set px=|[q`1*sqrt(1+(q`1/q`2)^2),q`2*sqrt(1+(q`1/q`2)^2)]|;
A17:      sqrt(1+(q`1/q`2)^2)>0 by Lm1,SQUARE_1:25;
A18:      now
            assume that
A19:        px`2=0 and
            px`1=0;
            q`2*sqrt(1+(q`1/q`2)^2)=0 by A19,EUCLID:52;
            then q`2=0 by A17,XCMPLX_1:6;
            hence contradiction by A16;
          end;
A20:      px`2 = q`2*sqrt(1+(q`1/q`2)^2) by EUCLID:52;
A21:      px`1 = q`1*sqrt(1+(q`1/q`2)^2) by EUCLID:52;
          then
A22:      px`1/px`2=q`1/q`2 by A20,A17,XCMPLX_1:91;
          then
A23:      px`1/sqrt(1+(px`1/px`2)^2)=q`1 by A21,A17,XCMPLX_1:89;
          q`1<=q`2 & -q`2<=q`1 or q`1>=q`2 & q`1<=-q`2 by A16,JGRAPH_2:13;
          then
          q`1<=q`2 & -q`2<=q`1 or q`1>=q`2 & q`1*sqrt(1+(q`1/q`2)^2) <= (
          -q`2)*sqrt(1+(q`1/q`2)^2) by A17,XREAL_1:64;
          then
          q`1<=q`2 & (-q`2)*sqrt(1+(q`1/q`2)^2) <= q`1*sqrt(1+(q`1/q`2)^2
          ) or px`1>=px`2 & px`1<=-px`2 by A20,A21,A17,XREAL_1:64;
          then q`1*sqrt(1+(q`1/q`2)^2) <= q`2*sqrt(1+(q`1/q`2)^2) & -px`2<=px
          `1 or px`1>=px`2 & px`1<=-px`2 by A20,A17,EUCLID:52,XREAL_1:64;
          then
A24:      Sq_Circ.px=|[px`1/sqrt(1+(px`1/px`2)^2),px`2/sqrt(1+( px`1/px`2
          )^2 )]| by A20,A21,A18,Th4,JGRAPH_2:3;
A25:      dom Sq_Circ=the carrier of TOP-REAL 2 by FUNCT_2:def 1;
          px`2/sqrt(1+(px`1/px`2)^2)=q`2 by A20,A17,A22,XCMPLX_1:89;
          hence ex x being set st x in dom Sq_Circ & y=Sq_Circ.x by A24,A23,A25
,EUCLID:53;
        end;
      end;
      hence thesis by A2,FUNCT_1:def 3;
    end;
    then
 rng f=the carrier of TOP-REAL 2;
     then
A26:  f is onto by FUNCT_2:def 3;
A27: rng f=dom ((f qua Function)") by A2,FUNCT_1:33
      .=dom (f/") by A2,A26,TOPS_2:def 4
      .=[#](TOP-REAL 2) by FUNCT_2:def 1;
    g=Sq_Circ" by A26,A2,TOPS_2:def 4;
    hence thesis by A2,A3,A27,Th21,Th42,TOPS_2:def 5;
  end;
  hence rng Sq_Circ=the carrier of TOP-REAL 2;
  thus thesis by A1;
end;
