reserve r,r1,r2,g,g1,g2,x0,t for Real;
reserve n,k for Nat;
reserve seq for Real_Sequence;
reserve f,f1,f2 for PartFunc of REAL,REAL;

theorem Th43:
  f is_left_convergent_in x0 implies r(#)f is_left_convergent_in
  x0 & lim_left(r(#)f,x0)=r*(lim_left(f,x0))
proof
  assume
A1: f is_left_convergent_in x0;
A2: now
    let seq;
    assume that
A3: seq is convergent and
A4: lim seq=x0 and
A5: rng seq c=dom(r(#)f)/\left_open_halfline(x0);
A6: rng seq c=dom f/\left_open_halfline(x0) by A5,VALUED_1:def 5;
A7: dom f/\left_open_halfline(x0) c=dom f by XBOOLE_1:17;
    then
A8: r(#) (f/*seq)=(r(#)f)/*seq by A6,RFUNCT_2:9,XBOOLE_1:1;
A9: f/*seq is convergent by A1,A3,A4,A6;
    then r(#)(f/*seq) is convergent;
    hence (r(#)f)/*seq is convergent by A6,A7,RFUNCT_2:9,XBOOLE_1:1;
    lim(f/*seq)=lim_left(f,x0) by A1,A3,A4,A6,Def7;
    hence lim((r(#)f)/*seq)=r*(lim_left(f,x0)) by A9,A8,SEQ_2:8;
  end;
  now
    let r1;
    assume r1<x0;
    then consider g such that
A10: r1<g and
A11: g<x0 and
A12: g in dom f by A1;
    take g;
    thus r1<g & g<x0 & g in dom(r(#)f) by A10,A11,A12,VALUED_1:def 5;
  end;
  hence r(#)f is_left_convergent_in x0 by A2;
  hence thesis by A2,Def7;
end;
