reserve i, j, m, n, k for Nat,
  x, y for set,
  K for Field,
  a,a1 for Element of K;
reserve V1,V2,V3 for finite-dimensional VectSp of K,
  f for Function of V1,V2,

  b1,b19 for OrdBasis of V1,
  B1 for FinSequence of V1,
  b2 for OrdBasis of V2,
  B2 for FinSequence of V2,

  B3 for FinSequence of V3,
  v1,w1 for Element of V1,
  R,R1,R2 for FinSequence of V1,
  p,p1,p2 for FinSequence of K;

theorem Th43:
  for V1,V2 be VectSp of K for f be linear-transformation of V1,V2
  holds f is one-to-one iff ker f = (0).V1
proof
  let V1,V2 be VectSp of K;
  let f be linear-transformation of V1,V2;
  ker f=(0).V1 implies f is one-to-one
  proof
    assume
A1: ker f=(0).V1;
    let x,y be object such that
A2: x in dom f & y in dom f and
A3: f.x=f.y;
    reconsider x9=x,y9=y as Element of V1 by A2,FUNCT_2:def 1;
    x9-y9 in ker f by A3,RANKNULL:17;
    then x9-y9 in the carrier of (0).V1 by A1;
    then x9-y9 in {0.V1} by VECTSP_4:def 3;
    then x9+-y9=0.V1 by TARSKI:def 1;
    hence x = --y9 by VECTSP_1:16
      .= y by RLVECT_1:17;
  end;
  hence thesis by RANKNULL:15;
end;
