reserve R for Ring,
  V for RightMod of R,
  a,b for Scalar of R,
  x,y for set,
  p,q ,r for FinSequence,
  i,k for Nat,
  u,v,v1,v2,v3,w for Vector of V,
  F,G,H for FinSequence of V,
  A,B for Subset of V,
  f for Function of V, R,
  S,T for finite Subset of V;
reserve L,L1,L2,L3 for Linear_Combination of V;
reserve l for Linear_Combination of A;
reserve RR for domRing;
reserve VV for RightMod of RR;
reserve LL for Linear_Combination of VV;
reserve aa for Scalar of RR;
reserve uu, vv for Vector of VV;

theorem Th43:
  aa <> 0.RR implies Carrier(LL * aa) = Carrier(LL)
proof
  set T = {uu : (LL * aa).uu <> 0.RR};
  set S = {vv : LL.vv <> 0.RR};
  assume
A1: aa <> 0.RR;
  T = S
  proof
    thus T c= S
    proof
      let x be object;
      assume x in T;
      then consider uu such that
A2:   x = uu and
A3:   (LL * aa).uu <> 0.RR;
      (LL * aa).uu = LL.uu * aa by Def10;
      then LL.uu <> 0.RR by A3;
      hence thesis by A2;
    end;
    let x be object;
    assume x in S;
    then consider vv such that
A4: x = vv and
A5: LL.vv <> 0.RR;
    (LL * aa).vv = LL.vv * aa by Def10;
    then (LL * aa).vv <> 0.RR by A1,A5,VECTSP_2:def 1;
    hence thesis by A4;
  end;
  hence thesis;
end;
