reserve x,x0, r,r1,r2 for Real,
      th for Real,

  rr for set,

  rseq for Real_Sequence;

theorem Th43:
  rng(cosec | [.-PI/2,-PI/4.]) = [.-sqrt 2,-1.]
proof
  now
    let y be object;
    thus y in [.-sqrt 2,-1.] implies
ex x be object st x in dom (cosec | [.-PI/2,
    -PI/4.]) & y = (cosec | [.-PI/2,-PI/4.]).x
    proof
      [.-PI/2,-PI/4.] c= [.-PI/2,0.[ by Lm7,XXREAL_2:def 12;
      then
A1:   cosec|[.-PI/2,-PI/4.] is continuous by Th39,FCONT_1:16;
      assume
A2:   y in [.-sqrt 2,-1.];
      then reconsider y1=y as Real;
A3:   -PI/2 <= -PI/4 by Lm7,XXREAL_1:3;
      y1 in [.cosec.(-PI/4),cosec.(-PI/2).] \/ [.cosec.(-PI/2),cosec.(-PI/
      4).] by A2,Th32,XBOOLE_0:def 3;
      then consider x be Real such that
A4:   x in [.-PI/2,-PI/4.] & y1 = cosec.x by A3,A1,Lm19,Th3,FCONT_2:15
,XBOOLE_1:1;
      take x;
      thus thesis by A4,Lm31,FUNCT_1:49;
    end;
    thus (ex x be object
st x in dom (cosec | [.-PI/2,-PI/4.]) & y = (cosec | [.-
    PI/2,-PI/4.]).x) implies y in [.-sqrt 2,-1.]
    proof
      given x be object such that
A5:   x in dom (cosec | [.-PI/2,-PI/4.]) and
A6:   y = (cosec | [.-PI/2,-PI/4.]).x;
      reconsider x1=x as Real by A5;
      y = cosec.x1 by A5,A6,Lm31,FUNCT_1:49;
      hence thesis by A5,Lm31,Th35;
    end;
  end;
  hence thesis by FUNCT_1:def 3;
end;
