
theorem
  for x, y be G_INTEG
  st Re y <> 0 & Im y <> 0 & Re y <> Im y & - Re y <> Im y
  & x*' is_associated_to y
  holds not x Divides y & not y Divides x
  proof
    let x, y be G_INTEG such that
    A1: Re y <> 0 & Im y <> 0 & Re y <> Im y & - Re y <> Im y and
    A2: x*' is_associated_to y;
    A3: x*' is_associated_to x implies y*' is_associated_to y
    proof
      assume A4: x*' is_associated_to x;
      then A5: x is_associated_to y by A2,Th42;
      then x*' is_associated_to y*' by Th43;
      then x is_associated_to y*' by A4,Th42;
      hence y*' is_associated_to y by A5,Th42;
    end;
    A6: Norm(x*') <> 0
    proof
      assume Norm(x*') = 0;
      then Norm(y) = 0 by A2,Lm10;
      hence contradiction by A1,Th36,COMPLEX1:4;
    end;
    hereby
      consider c being G_INTEG such that
      A7: c is g_int_unit and
      A8: x*' = c * y by A2,Th40;
      assume x Divides y;
      then consider d being G_INTEG such that
      A9: y = x * d;
      A10: x*' = (c*d) * x by A8,A9;
      reconsider e = c*d as G_INTEG;
      A11: Norm(e) = Norm(c)*Norm(d) by Th34
      .= Norm(d) by A7;
      per cases;
      suppose d is g_int_unit;
        hence contradiction
        by A3,A1,A10,A11,Def20,Th40,Th41;
      end;
      suppose A12: not d is g_int_unit;
        Norm(x*') = Norm(e) * Norm(x) by A10,Th34;
        hence contradiction by A11,A12,A6,XCMPLX_1:7;
      end;
    end;
    consider c being G_INTEG such that
    A13: c is g_int_unit and
    A14: y = c * x*' by A2,Th40;
    assume y Divides x;
    then consider d being G_INTEG such that
    A15: x = y * d;
    A16: x = (c*d) * x*' by A14,A15;
    reconsider e = c*d as G_INTEG;
    A17: Norm(e) = Norm(c)*Norm(d) by Th34
    .= Norm(d) by A13;
    per cases;
    suppose d is g_int_unit;
      hence contradiction
      by A3,A1,A16,A17,Def20,Th40,Th41;
    end;
    suppose A18: not d is g_int_unit;
      Norm(x) = Norm(e) * Norm(x*') by A16,Th34;
      hence contradiction by A17,A18,A6,XCMPLX_1:7;
    end;
  end;
