
theorem
  for G2 being _Graph, V being Subset of the_Vertices_of G2
  for G1 being addLoops of G2, V, v1 being Vertex of G1, v2 being Vertex of G2
  st v1 = v2 & not v1 in V holds
    v1.edgesIn() = v2.edgesIn() & v1.inDegree() = v2.inDegree() &
    v1.edgesOut() = v2.edgesOut() & v1.outDegree() = v2.outDegree() &
    v1.edgesInOut() = v2.edgesInOut() & v1.degree() = v2.degree()
proof
  let G2 be _Graph, V be Subset of the_Vertices_of G2;
  let G1 be addLoops of G2, V, v1 be Vertex of G1, v2 be Vertex of G2;
  assume A1: v1 = v2 & not v1 in V;
  consider E being set, f being one-to-one Function such that
    A2: E misses the_Edges_of G2 & the_Edges_of G1 = the_Edges_of G2 \/ E and
    A3: dom f = E & rng f = V & the_Source_of G1 = the_Source_of G2 +* f and
    A4: the_Target_of G1 = the_Target_of G2 +* f by Def5;
  A5: G2 is Subgraph of G1 by GLIB_006:57;
  then A6: v2.edgesIn() c= v1.edgesIn() by A1, GLIB_000:78;
  now
    let e be object;
    assume e in v1.edgesIn();
    then consider x being set such that
      A7: e DJoins x,v1,G1 by GLIB_000:57;
    e in the_Edges_of G2
    proof
      assume A8: not e in the_Edges_of G2;
      e in the_Edges_of G1 by A7, GLIB_000:def 14;
      then A9: e in E by A2, A8, XBOOLE_0:def 3;
      v1 = (the_Target_of G1).e by A7, GLIB_000:def 14
        .= f.e by A3, A4, A9, FUNCT_4:13;
      hence contradiction by A1, A3, A9, FUNCT_1:3;
    end;
    hence e in v2.edgesIn() by A1, A7, GLIB_006:71, GLIB_000:57;
  end;
  then v1.edgesIn() c= v2.edgesIn() by TARSKI:def 3;
  hence A10: v1.edgesIn() = v2.edgesIn() by A6, XBOOLE_0:def 10;
  hence v1.inDegree() = v2.inDegree();
  A11: v2.edgesOut() c= v1.edgesOut() by A1, A5, GLIB_000:78;
  now
    let e be object;
    assume e in v1.edgesOut();
    then consider x being set such that
      A12: e DJoins v1,x,G1 by GLIB_000:59;
    e in the_Edges_of G2
    proof
      assume A13: not e in the_Edges_of G2;
      e in the_Edges_of G1 by A12, GLIB_000:def 14;
      then A14: e in E by A2, A13, XBOOLE_0:def 3;
      v1 = (the_Source_of G1).e by A12, GLIB_000:def 14
        .= f.e by A3, A14, FUNCT_4:13;
      hence contradiction by A1, A3, A14, FUNCT_1:3;
    end;
    hence e in v2.edgesOut() by A1, A12, GLIB_006:71, GLIB_000:59;
  end;
  then v1.edgesOut() c= v2.edgesOut() by TARSKI:def 3;
  hence A15: v1.edgesOut() = v2.edgesOut() by A11, XBOOLE_0:def 10;
  hence v1.outDegree() = v2.outDegree();
  thus thesis by A10, A15;
end;
