reserve n for Nat,
  i,j for Nat,
  r,s,r1,s1,r2,s2,r9,s9 for Real,
  p,q for Point of TOP-REAL 2,
  G for Go-board,
  x,y for set,
  v for Point of Euclid 2;

theorem Th44:
  1 <= j & j < width G implies LSeg(1/2*(G*(1,j)+G*(1,j+1)) - |[1,
0]|,1/2*(G*(1,j)+G*(1,j+1))) c= Int cell(G,0,j) \/ { 1/2*(G*(1,j)+G*(1,j+1)) }
proof
  assume that
A1: 1 <= j and
A2: j < width G;
  let x be object;
  assume
A3: x in LSeg(1/2*(G*(1,j)+G*(1,j+1))-|[1,0]|,1/2*(G*(1,j)+G*(1,j+1)));
  then reconsider p = x as Point of TOP-REAL 2;
  consider r such that
A4: p = (1-r)*(1/2*(G*(1,j)+G*(1,j+1))-|[1,0]|)+r*(1/2*(G*(1,j)+G* (1,j+
  1))) and
A5: 0<=r and
A6: r<=1 by A3;
  now
    per cases by A6,XXREAL_0:1;
    case
      r = 1;
      then p = 0.TOP-REAL 2 + 1*(1/2*(G*(1,j)+G*(1,j+1))) by A4,RLVECT_1:10

        .= 1*(1/2*(G*(1,j)+G*(1,j+1))) by RLVECT_1:4
        .= 1/2*(G*(1,j)+G*(1,j+1)) by RLVECT_1:def 8;
      hence p in { 1/2*(G*(1,j)+G*(1,j+1)) } by TARSKI:def 1;
    end;
    case
A7:   r < 1;
      set r3 = (1-r)*(1/2), s3 = r*(1/2);
      set r2 = G*(1,1)`1, s1 = G*(1,j)`2, s2 = G*(1,j+1)`2;
A8:   r3*(s1+s1)+s3*(s1+s1) = s1;
A9:   j+1 <= width G by A2,NAT_1:13;
      0 <> len G by MATRIX_0:def 10;
      then
A10:  1 <= len G by NAT_1:14;
      j < j+1 by XREAL_1:29;
      then
A11:  s1 < s2 by A1,A9,A10,GOBOARD5:4;
      then
A12:  s1+s1 < s1+s2 by XREAL_1:6;
      then
A13:  s3*(s1+s1) <= s3*(s1+s2) by A5,XREAL_1:64;
A14:  1 - r > 0 by A7,XREAL_1:50;
      then
A15:  r3 > (1/2)*0 by XREAL_1:68;
      then r3*(s1+s1) < r3*(s1+s2) by A12,XREAL_1:68;
      then
A16:  s1 < r3*(s1+s2)+s3*(s1+s2) by A13,A8,XREAL_1:8;
      r2 < r2+(1-r) by A14,XREAL_1:29;
      then
A17:  r2-(1-r) < r2 by XREAL_1:19;
A18:  1 <= j+1 by A1,NAT_1:13;
A19:  G*(1,j+1) = |[G*(1,j+1)`1,G*(1,j+1)`2]| by EUCLID:53
        .= |[r2,s2]| by A18,A9,A10,GOBOARD5:2;
A20:  s1+s2 < s2+s2 by A11,XREAL_1:6;
      then
A21:  s3*(s1+s2) <= s3*(s2+s2) by A5,XREAL_1:64;
A22:  Int cell(G,0,j) = { |[r9,s9]| : r9 < G*(1,1)`1 & G*(1,j)`2 < s9 &
      s9 < G*(1,j+1)`2 } by A1,A2,Th20;
A23:  r3*(s2+s2)+s3*(s2+s2) = s2;
      r3*(s1+s2) < r3*(s2+s2) by A15,A20,XREAL_1:68;
      then
A24:  r3*(s1+s2)+s3*(s1+s2) < s2 by A21,A23,XREAL_1:8;
A25:  G*(1,j) = |[G*(1,j)`1,G*(1,j)`2]| by EUCLID:53
        .= |[r2,s1]| by A1,A2,A10,GOBOARD5:2;
      p = (1-r)*(1/2*(G*(1,j)+G*(1,j+1)))-(1-r)*|[1,0]| +r*(1/2*(G*(1,j)+
      G*(1,j+1))) by A4,RLVECT_1:34
        .= r3*(G*(1,j)+G*(1,j+1))-(1-r)*|[1,0]|+r*(1/2*(G*(1,j)+G*(1,j+1)))
      by RLVECT_1:def 7
        .= r3*(G*(1,j)+G*(1,j+1))-|[(1-r)*1,(1-r)*0]|+r*(1/2*(G*(1,j)+G* (1,
      j+1))) by EUCLID:58
        .= r3*(G*(1,j)+G*(1,j+1))-|[1-r,0]|+s3*(G*(1,j)+G* (1,j+1)) by
RLVECT_1:def 7
        .= r3*|[r2+r2,s1+s2]|-|[1-r,0]|+s3*(G*(1,j)+G*(1,j+1)) by A19,A25,
EUCLID:56
        .= r3*|[r2+r2,s1+s2]|-|[1-r,0]|+s3*|[r2+r2,s1+s2]| by A19,A25,EUCLID:56
        .= |[r3*(r2+r2),r3*(s1+s2)]|-|[1-r,0]|+s3*|[r2+r2,s1+s2]| by EUCLID:58
        .= |[r3*(r2+r2),r3*(s1+s2)]|-|[1-r,0]|+|[s3*(r2+r2),s3*(s1+s2)]| by
EUCLID:58
        .= |[r3*(r2+r2)-(1-r),r3*(s1+s2)-0]|+|[s3*(r2+r2),s3*(s1+s2)]| by
EUCLID:62
        .= |[r3*(r2+r2)-(1-r)+s3*(r2+r2),r3*(s1+s2)+s3*(s1+s2)]| by EUCLID:56;
      hence p in Int cell(G,0,j) by A17,A16,A24,A22;
    end;
  end;
  hence thesis by XBOOLE_0:def 3;
end;
