reserve A for Tolerance_Space,
  X, Y for Subset of A;
reserve A for Approximation_Space,
  X for Subset of A;
reserve A for finite Tolerance_Space,
  X for Subset of A,
  x for Element of A;
reserve A for finite Approximation_Space,
  X, Y for Subset of A,
  x for Element of A;

theorem
  for A being discrete finite Approximation_Space, X being Subset of A
  holds MemberFunc (X, A) = chi (X, the carrier of A)
proof
  let A be discrete finite Approximation_Space, X be Subset of A;
  reconsider F = MemberFunc (X, A) as Function of the carrier of A, REAL;
  set G = chi (X, the carrier of A);
  {In(0,REAL),In(1,REAL)} c= REAL;
  then reconsider G as Function of the carrier of A, REAL by FUNCT_2:7;
  for x being object st x in the carrier of A holds F.x = G.x
  proof
    let x be object;
    assume
A1: x in the carrier of A;
    per cases;
    suppose
A2:   x in X;
      then x in LAp X by Th15;
      then F.x = 1 by Th40;
      hence thesis by A2,FUNCT_3:def 3;
    end;
    suppose
A3:   not x in X;
      then not x in UAp X by Th16;
      then x in (UAp X)` by A1,XBOOLE_0:def 5;
      then F.x = 0 by Th41;
      hence thesis by A1,A3,FUNCT_3:def 3;
    end;
  end;
  hence thesis by FUNCT_2:12;
end;
