reserve T for non empty TopSpace,
  A, B for Subset of T,
  F, G for Subset-Family of T,
  x for set;

theorem
  for T being non empty TopSpace st T is T_1 holds ex A, B being Subset
  of T st A \/ B = [#]T & A misses B & A is perfect & B is scattered
proof
  let T be non empty TopSpace;
  defpred P[Subset of T] means $1 is dense-in-itself;
  consider CC being Subset-Family of T such that
A1: for A being Subset of T holds A in CC iff P[A] from SUBSET_1:sch 3;
  set C = union CC;
A2: [#]T = C \/ C` & C misses C` by PRE_TOPC:2,XBOOLE_1:79;
A3: CC is dense-in-itself by A1;
  assume T is T_1;
  then Cl C is dense-in-itself by A3,Th36,Th38;
  then Cl C in CC by A1;
  then
A4: Cl C c= C by ZFMISC_1:74;
  C c= Cl C by PRE_TOPC:18;
  then
A5: Cl C = C by A4;
  not ex B being Subset of T st B is non empty & B c= C` & B is dense-in-itself
  proof
    given B being Subset of T such that
A6: B is non empty and
A7: B c= C` & B is dense-in-itself;
    B misses union CC & B in CC by A1,A7,SUBSET_1:23;
    hence thesis by A6,XBOOLE_1:69,ZFMISC_1:74;
  end;
  then
A8: C` is scattered;
  C is dense-in-itself by A3,Th38;
  hence thesis by A5,A8,A2;
end;
