reserve a,b,c for set;
reserve r for Real,
  X for set,
  n for Element of NAT;

theorem Th44:
  for X be set, X0 being Subset of X holds the topology of X0
  -DiscreteTop X = {X} \/ bool X0
proof
  let X be set;
  let X0 be Subset of X;
A1: the carrier of X0-DiscreteTop X = X by Def8;
  thus the topology of X0-DiscreteTop X c= {X} \/ bool X0
  proof
    let a be object;
    assume
A2: a in the topology of X0-DiscreteTop X;
    then reconsider a as Subset of X0-DiscreteTop X;
A3: a is proper & X is non empty or a is not proper by A1;
    a is open by A2;
    then a = X or a c= X0 by A3,A1,Th43;
    then a in {X} or a in bool X0 by TARSKI:def 1;
    hence thesis by XBOOLE_0:def 3;
  end;
  let a be object;
   reconsider aa=a as set by TARSKI:1;
  assume a in {X} \/ bool X0;
  then
A4: a in {X} or a in bool X0 by XBOOLE_0:def 3;
  then a = X or aa c= X0 by TARSKI:def 1;
  then reconsider a as Subset of X0-DiscreteTop X by A1,XBOOLE_1:1;
  assume
A5: not thesis;
  then
A6: a <> [#](X0-DiscreteTop X) by PRE_TOPC:def 2;
  then
A7: X is non empty by A1;
A8: a is proper by A6;
A9: a is not open by A5;
  a <> X by A6,Def8;
  hence thesis by A7,A4,A9,A8,Th43,TARSKI:def 1;
end;
