reserve N for Nat;
reserve n,m,n1,n2 for Nat;
reserve q,r,r1,r2 for Real;
reserve x,y for set;
reserve w,w1,w2,g,g1,g2 for Point of TOP-REAL N;
reserve seq,seq1,seq2,seq3,seq9 for Real_Sequence of N;

theorem
  seq is convergent implies seq is bounded
proof
  assume seq is convergent;
  then consider g such that
A1: for r st 0<r ex n st for m st n<=m holds |.seq.m-g.|<r;
  consider n1 such that
A2: for m st n1<=m holds |.seq.m-g.|<1 by A1;
A3: now
    take r=|.g.|+1;
    thus 0<r;
    let m;
A4: |.seq.m.|-|.g.|+|.g.|=|.seq.m.|;
    assume n1<=m;
    then
A5: |.seq.m-g.|<1 by A2;
    |.seq.m.|-|.g.|<=|.seq.m-g.| by Th32;
    then |.seq.m.|-|.g.|<1 by A5,XXREAL_0:2;
    hence |.seq.m.|<r by A4,XREAL_1:6;
  end;
  now
    consider r2 such that
A6: 0<r2 and
A7: for m st m<=n1 holds |.seq.m.|<r2 by Th35;
    consider r1 such that
A8: 0<r1 and
A9: for m st n1<=m holds |.seq.m.|<r1 by A3;
    take r=r1+r2;
    thus 0<r by A8,A6;
    let m;
A10: 0+r2<r by A8,XREAL_1:8;
A11: now
      assume m<=n1;
      then |.seq.m.|<r2 by A7;
      hence |.seq.m.|<r by A10,XXREAL_0:2;
    end;
A12: r1+0<r by A6,XREAL_1:8;
    now
      assume n1<=m;
      then |.seq.m.|<r1 by A9;
      hence |.seq.m.|<r by A12,XXREAL_0:2;
    end;
    hence |.seq.m.|<r by A11;
  end;
  hence thesis;
end;
