reserve x, y for set,
  T for TopStruct,
  GX for TopSpace,
  P, Q, M, N for Subset of T,
  F, G for Subset-Family of T,
  W, Z for Subset-Family of GX,
  A for SubSpace of T;
reserve S for non empty TopStruct,
  f for Function of T, S,
  H for Subset-Family of S;

theorem Th44:
  for T being TopSpace, S being TopSpace, f being Function of T, S
holds f is continuous iff for P1 being Subset of S holds Cl(f"P1) c= f"(Cl P1)
proof
  let T be TopSpace, S be TopSpace, f be Function of T, S;
  hereby
    assume
A1: f is continuous;
    let P1 be Subset of S;
    Cl(Cl P1) = Cl P1;
    then Cl P1 is closed by PRE_TOPC:22;
    then
A2: f"(Cl P1) is closed by A1;
    f"P1 c= f"(Cl P1) by PRE_TOPC:18,RELAT_1:143;
    then Cl(f"P1) c= Cl(f"(Cl P1)) by PRE_TOPC:19;
    hence Cl(f"P1) c= f"(Cl P1) by A2,PRE_TOPC:22;
  end;
  assume
A3: for P1 being Subset of S holds Cl(f"P1) c= f"(Cl P1);
  let P1 be Subset of S;
  assume P1 is closed;
  then Cl P1 = P1 by PRE_TOPC:22;
  then f"P1 c= Cl(f"P1) & Cl(f"P1) c= f"P1 by A3,PRE_TOPC:18;
  then f"P1 = Cl(f"P1) by XBOOLE_0:def 10;
  hence thesis by PRE_TOPC:22;
end;
