reserve n,n1,m,m1,k for Nat;
reserve x,X,X1 for set;
reserve g,g1,g2,t,x0,x1,x2 for Complex;
reserve s1,s2,q1,seq,seq1,seq2,seq3 for Complex_Sequence;
reserve Y for Subset of COMPLEX;
reserve f,f1,f2,h,h1,h2 for PartFunc of COMPLEX,COMPLEX;
reserve p,r,s for Real;
reserve Ns,Nseq for increasing sequence of NAT;

theorem Th45:
  for g,X,f st f is_continuous_on X holds g(#)f is_continuous_on X
proof
  let g,X,f;
  assume
A1: f is_continuous_on X;
  then
A2: X c= dom f;
  then
A3: X c= dom(g(#)f) by CFUNCT_1:4;
  now
    let s1;
    assume that
A4: rng s1 c= X and
A5: s1 is convergent and
A6: lim s1 in X;
A7: f/*s1 is convergent by A1,A4,A5,A6,Th38;
    then
A8: g(#)(f/*s1) is convergent;
A9: lim s1 in dom(g(#)f) by A3,A6;
    f/.(lim s1) = lim (f/*s1) by A1,A4,A5,A6,Th38;
    then (g(#)f)/.(lim s1) = g * lim (f/*s1) by CFUNCT_1:4,A9
      .= lim (g(#)(f/*s1)) by A7,COMSEQ_2:18
      .= lim ((g(#)f)/*s1) by A2,A4,Th8,XBOOLE_1:1;
    hence
    (g(#)f)/*s1 is convergent & (g(#)f)/.(lim s1)=lim((g(#)f)/*s1) by A2,A4,A8
,Th8,XBOOLE_1:1;
  end;
  hence thesis by A3,Th38;
end;
