
theorem Th45:
  for C1, C2 being Coherence_Space for A being set st for x,y
being set st x in A & y in A ex f being U-stable Function of C1,C2 st x \/ y =
  Trace f ex f being U-stable Function of C1,C2 st union A = Trace f
proof
  let C1, C2 be Coherence_Space;
  let A be set such that
A1: for x,y being set st x in A & y in A ex f being U-stable Function of
  C1,C2 st x \/ y = Trace f;
  set X = union A;
A2: now
    let a,b be Element of C1 such that
A3: a \/ b in C1;
    let y1,y2 be object;
    assume [a,y1] in X;
    then consider x1 being set such that
A4: [a,y1] in x1 and
A5: x1 in A by TARSKI:def 4;
    assume [b,y2] in X;
    then consider x2 being set such that
A6: [b,y2] in x2 and
A7: x2 in A by TARSKI:def 4;
A8: x1 c= x1 \/ x2 & x2 c= x1 \/ x2 by XBOOLE_1:7;
    ex f being U-stable Function of C1,C2 st x1 \/ x2 = Trace f by A1,A5,A7;
    hence {y1,y2} in C2 by A3,A4,A6,A8,Th34;
  end;
A9: now
    let a,b be Element of C1 such that
A10: a \/ b in C1;
    let y be object;
    assume [a,y] in X;
    then consider x1 being set such that
A11: [a,y] in x1 and
A12: x1 in A by TARSKI:def 4;
    assume [b,y] in X;
    then consider x2 being set such that
A13: [b,y] in x2 and
A14: x2 in A by TARSKI:def 4;
A15: x1 c= x1 \/ x2 & x2 c= x1 \/ x2 by XBOOLE_1:7;
    ex f being U-stable Function of C1,C2 st x1 \/ x2 = Trace f by A1,A12,A14;
    hence a = b by A10,A11,A13,A15,Th35;
  end;
A16: now
    let x be set;
    assume x in X;
    then consider y being set such that
A17: x in y and
A18: y in A by TARSKI:def 4;
    y \/ y = y;
    then consider f being U-stable Function of C1,C2 such that
A19: y = Trace f by A1,A18;
    consider a, y being set such that
A20: x = [a,y] and
    a in dom f and
    y in f.a and
    for b being set st b in dom f & b c= a & y in f.b holds a = b by A17,A19
,Def17;
    dom f = C1 by FUNCT_2:def 1;
    then a is finite by A17,A19,A20,Th33;
    hence x`1 is finite by A20;
  end;
  X c= [:C1, union C2:]
  proof
    let x be object;
    assume x in X;
    then consider y being set such that
A21: x in y and
A22: y in A by TARSKI:def 4;
    y \/ y = y;
    then ex f being U-stable Function of C1,C2 st y = Trace f by A1,A22;
    hence thesis by A21;
  end;
  hence thesis by A16,A2,A9,Th38;
end;
