reserve x,y for set,
  i for Nat;
reserve V for non empty CLSStruct,
  u,v,v1,v2,v3 for VECTOR of V,
  A for Subset of V,
  l, l1, l2 for C_Linear_Combination of A,
  x,y,y1,y2 for set,
  a,b for Complex,
  F for FinSequence of the carrier of V,
  f for Function of the carrier of V, COMPLEX;
reserve K,L,L1,L2,L3 for C_Linear_Combination of V;
reserve e,e1,e2 for Element of C_LinComb V;

theorem
  for V being vector-distributive scalar-distributive scalar-associative
  scalar-unital non empty CLSStruct, M being
  Subset of V, z being Complex st M is convex holds z*M is convex
proof
  let V be vector-distributive scalar-distributive scalar-associative
  scalar-unital non empty CLSStruct;
  let M be Subset of V;
  let z be Complex;
  assume
A1: M is convex;
  for u,v being VECTOR of V, s being Complex st (ex p being Real st s=p &
  0 < p & p < 1) & u in z*M & v in z*M holds s*u + (1r-s)*v in z*M
  proof
    let u,v be VECTOR of V;
    let s be Complex;
    assume that
A2: ex p being Real st s=p & 0 < p & p < 1 and
A3: u in z*M and
A4: v in z*M;
    consider v9 be Element of V such that
A5: v = z*v9 and
A6: v9 in M by A4;
    consider u9 be Element of V such that
A7: u = z * u9 and
A8: u9 in M by A3;
A9: s*u + (1r-s)*v = s*z*u9 + (1r-s)*(z*v9) by A7,A5,CLVECT_1:def 4
      .= z*s*u9 + z*(1r-s)*v9 by CLVECT_1:def 4
      .= z*(s*u9) + z*(1r-s)*v9 by CLVECT_1:def 4
      .= z*(s*u9) + z*((1r-s)*v9) by CLVECT_1:def 4
      .= z*(s*u9 + (1r-s)*v9) by CLVECT_1:def 2;
    s*u9 + (1r-s)*v9 in M by A1,A2,A8,A6;
    hence thesis by A9;
  end;
  hence thesis;
end;
