reserve x for Real,

  Z for open Subset of REAL;

theorem
  Z c= dom (sin*cosec) implies sin*cosec is_differentiable_on Z & for x
  st x in Z holds ((sin*cosec)`|Z).x = -cos.(cosec.x)*cos.x/(sin.x)^2
proof
  assume
A1: Z c= dom (sin*cosec);
  dom (sin*cosec) c= dom cosec by RELAT_1:25;
  then
A2: Z c= dom cosec by A1,XBOOLE_1:1;
A3: for x st x in Z holds sin*cosec is_differentiable_in x
  proof
    let x;
    assume x in Z;
    then sin.x<>0 by A2,RFUNCT_1:3;
    then
A4: cosec is_differentiable_in x by FDIFF_9:2;
    sin is_differentiable_in cosec.x by SIN_COS:64;
    hence thesis by A4,FDIFF_2:13;
  end;
  then
A5: sin*cosec is_differentiable_on Z by A1,FDIFF_1:9;
  for x st x in Z holds ((sin*cosec)`|Z).x = -cos.(cosec.x)*cos.x/(sin.x) ^2
  proof
    let x;
A6: sin is_differentiable_in cosec.x by SIN_COS:64;
    assume
A7: x in Z;
    then
A8: sin.x <>0 by A2,RFUNCT_1:3;
    then cosec is_differentiable_in x by FDIFF_9:2;
    then diff(sin*cosec,x) = diff(sin,cosec.x)*diff(cosec,x) by A6,FDIFF_2:13
      .= cos(cosec.x)*diff(cosec,x) by SIN_COS:64
      .= cos(cosec.x)* (-cos.x/(sin.x)^2) by A8,FDIFF_9:2
      .=-cos.(cosec.x)*cos.x/(sin.x)^2;
    hence thesis by A5,A7,FDIFF_1:def 7;
  end;
  hence thesis by A1,A3,FDIFF_1:9;
end;
