reserve E, x, y, X for set;
reserve A, B, C for Subset of E^omega;
reserve a, a1, a2, b for Element of E^omega;
reserve i, k, l, m, n for Nat;

theorem Th45:
  (A |^.. k) \/ (B |^.. k) c= (A \/ B) |^.. k
proof
  let x be object;
    assume
A1: x in (A |^.. k) \/ (B |^.. k);
    per cases by A1,XBOOLE_0:def 3;
    suppose
      x in (A |^.. k);
      then consider m such that
A2:   k <= m and
A3:   x in A |^ m by Th2;
A4:   (A |^ m) \/ (B |^ m) c= (A \/ B) |^ m by FLANG_1:38;
      A |^ m c= (A |^ m) \/ (B |^ m) by XBOOLE_1:7;
      then A |^ m c= (A \/ B) |^ m by A4;
      then
A5:   x in (A \/ B) |^ m by A3;
      (A \/ B) |^ m c= (A \/ B) |^.. k by A2,Th3;
      hence thesis by A5;
    end;
    suppose
      x in (B |^.. k);
      then consider m such that
A6:   k <= m and
A7:   x in B |^ m by Th2;
A8:   (A |^ m) \/ (B |^ m) c= (A \/ B) |^ m by FLANG_1:38;
      B |^ m c= (A |^ m) \/ (B |^ m) by XBOOLE_1:7;
      then B |^ m c= (A \/ B) |^ m by A8;
      then
A9:   x in (A \/ B) |^ m by A7;
      (A \/ B) |^ m c= (A \/ B) |^.. k by A6,Th3;
      hence thesis by A9;
    end;
end;
