reserve n for Element of NAT;
reserve i for Integer;
reserve G,H,I for Group;
reserve A,B for Subgroup of G;
reserve N for normal Subgroup of G;
reserve a,a1,a2,a3,b,b1 for Element of G;
reserve c,d for Element of H;
reserve f for Function of the carrier of G, the carrier of H;
reserve x,y,y1,y2,z for set;
reserve A1,A2 for Subset of G;
reserve N for normal Subgroup of G;
reserve S,T1,T2 for Element of G./.N;
reserve g,h for Homomorphism of G,H;
reserve h1 for Homomorphism of H,I;

theorem Th45:
  for x being object holds x in Image g iff ex a st x = g.a
proof let x be object;
  thus x in Image g implies ex a st x = g.a
  proof
    assume x in Image g;
    then x in the carrier of Image g;
    then x in g .: (the carrier of G) by Def10;
    then consider y being object such that
    y in dom g and
A1: y in the carrier of G and
A2: g.y = x by FUNCT_1:def 6;
    reconsider y as Element of G by A1;
    take y;
    thus thesis by A2;
  end;
  given a such that
A3: x = g.a;
  the carrier of G = dom g by FUNCT_2:def 1;
  then x in g .: (the carrier of G) by A3,FUNCT_1:def 6;
  then x in the carrier of Image g by Def10;
  hence thesis;
end;
