reserve n for Nat;

theorem
  for C be compact non vertical non horizontal Subset of TOP-REAL 2 for
p,q be Point of TOP-REAL 2 st p in BDD L~Cage(C,n) ex B be S-Sequence_in_R2 st
B = B_Cut(Rotate(Cage(C,n),Cage(C,n)/.Index(South-Bound(p,L~Cage(C,n)), Cage(C,
n)))|(len Rotate(Cage(C,n),Cage(C,n)/. Index(South-Bound(p,L~Cage(C,n)), Cage(C
  ,n)))-'1),South-Bound(p,L~Cage(C,n)),North-Bound(p,L~Cage(C,n))) & ex P be
  S-Sequence_in_R2 st P is_sequence_on GoB(B^'<*North-Bound(p,L~Cage(C,n)),
South-Bound(p,L~Cage(C,n))*>) & L~<*North-Bound(p,L~Cage(C,n)),South-Bound(p,L~
Cage(C,n))*> = L~P & P/.1 = North-Bound(p,L~Cage(C,n)) & P/.len P = South-Bound
  (p,L~Cage(C,n)) & len P >= 2 & ex B1 be S-Sequence_in_R2 st B1 is_sequence_on
GoB(B^'<*North-Bound(p,L~Cage(C,n)),South-Bound(p,L~Cage(C,n))*>) & L~B = L~B1
& B/.1 = B1/.1 & B/.len B = B1/.len B1 & len B <= len B1 & ex g be non constant
  standard special_circular_sequence st g = B1^'P
proof
  let C be compact non vertical non horizontal Subset of TOP-REAL 2;
  let p,q be Point of TOP-REAL 2;
  set f = Cage(C,n);
  set Lf = L~f;
  set a = North-Bound(p,Lf);
  set b = South-Bound(p,Lf);
  set Rotf = Rotate(f,f/.Index(b,f));
  set rf = Rotf|(len Rotf-'1);
A1: L~Rotf = L~f by REVROT_1:33;
A2: LSeg(Rotf,len Rotf -' 1) /\ LSeg(Rotf,1) = {Rotf/.1} by GOBOARD7:34
,REVROT_1:30;
  then
A3: LSeg(Rotf,len Rotf -' 1) meets LSeg(Rotf,1);
A4: Rotf/.2 in LSeg(Rotf/.2,Rotf/.1) by RLTOPSP1:68;
  len Rotf >=1+1 by GOBOARD7:34,XXREAL_0:2;
  then
A5: LSeg(Rotf,1) = LSeg(Rotf/.1,Rotf/.(1+1)) by TOPREAL1:def 3;
A6: b`1 = p`1 by JORDAN18:16;
  len f > 4 by GOBOARD7:34;
  then
A7: len f-'1+1 = len f by XREAL_1:235,XXREAL_0:2;
  then
A8: len f-'1 < len f by NAT_1:13;
  set pion = <*a,b*>;
A9: len f > 1 by GOBOARD7:34,XXREAL_0:2;
A10: Rotf/.(len Rotf-'1) in LSeg(Rotf/.(len Rotf-'1),Rotf/.(len Rotf)) by
RLTOPSP1:68;
  assume that
A11: p in BDD Lf;
A12: a <> b by A11,JORDAN18:20;
A13: b in Lf by A11,JORDAN18:17;
  then
A14: Index(b,f) < len f by JORDAN3:8;
A15: for i be Nat st 1 <= i & i < Index(b,f) holds f/.i <> f/.Index(b,f)
  by A14,GOBOARD7:36;
  1<=Index(b,f) by A13,JORDAN3:8;
  then
A16: Index(b,f) in dom f by A14,FINSEQ_3:25;
  then f/.Index(b,f)..f <= Index(b,f) by FINSEQ_5:39;
  then 0+(f/.Index(b,f))..f < len f by A14,XXREAL_0:2;
  then
A17: len f - (f/.Index(b,f))..f > 1-1 by XREAL_1:20;
A18: f/.Index(b,f) in rng f by A16,PARTFUN2:2;
  then len(f:-(f/.Index(b,f)))=len f-(f/.Index(b,f))..f+1 by FINSEQ_5:50;
  then 1 < len(f:-(f/.Index(b,f))) by A17,XREAL_1:19;
  then
A19: LSeg(Rotate(f,f/.Index(b,f)),1) = LSeg(f,1 -' 1 + (f/.Index(b,f)) ..f)
  by A18,REVROT_1:24
    .= LSeg(f,0+(f/.Index(b,f))..f) by XREAL_1:232
    .= LSeg(f,Index(b,f)) by A16,A15,FINSEQ_6:48;
  then
A20: b in LSeg(Rotate(f,f/.Index(b,f)),1) by A13,JORDAN3:9;
A21: len f > 1+1 by GOBOARD7:34,XXREAL_0:2;
  then
A22: len f-1 > 1 by XREAL_1:20;
  then
A23: 1 < len f-'1 by XREAL_0:def 2;
A24: len Rotf = len f by FINSEQ_6:179;
  then
A25: LSeg(Rotf,1) = LSeg(Rotf/.1,Rotf/.(1+1)) by A21,TOPREAL1:def 3;
A26: a`1 = p`1 by JORDAN18:16;
  then LSeg(a,b) is vertical by A6,SPPOL_1:16;
  then
A27: pion is being_S-Seq by A12,JORDAN1B:7;
A28: p`2 < a`2 by A11,JORDAN18:18;
A29: b`2 < p`2 by A11,JORDAN18:18;
  then
A30: p in LSeg(a,b) by A26,A6,A28,GOBOARD7:7;
A31: LSeg(Rotf,len Rotf-'1) = LSeg(Rotf/.(len Rotf-'1),Rotf/.(len Rotf)) by A24
,A22,A7,TOPREAL1:def 3;
  reconsider rf as S-Sequence_in_R2 by A24,A22,A7,JORDAN4:37;
A32: L~Rotf = L~rf \/ LSeg(Rotf,len Rotf-'1) by A24,A22,A7,GOBOARD2:3;
A33: Rotf/.1 = Rotf/.len Rotf by FINSEQ_6:def 1;
A34: b`2 < a`2 by A29,A28,XXREAL_0:2;
A35: now
    assume
A36: a in LSeg(Rotf,len Rotf-'1);
    per cases by SPPOL_1:19;
    suppose
A37:  LSeg(Rotf,1) is vertical & LSeg(Rotf,len Rotf-'1) is vertical;
      then
A38:  b`1 = (Rotf/.1)`1 by A13,A19,A25,JORDAN3:9,SPPOL_1:41;
A39:  (Rotf/.1)`1 = (Rotf/.(1+1))`1 by A25,A37,SPPOL_1:16;
A40:  (Rotf/.(len Rotf-'1))`1 = (Rotf/.(len Rotf))`1 by A31,A37,SPPOL_1:16;
      per cases by A34,XXREAL_0:2;
      suppose
A41:    b`2 < (Rotf/.1)`2;
        then
A42:    (b`2+(Rotf/.1)`2)/2 < (Rotf/.1)`2 by XREAL_1:226;
A43:    b`2 < (b`2+(Rotf/.1)`2)/2 by A41,XREAL_1:226;
        set p1 = |[(Rotf/.1)`1,(b`2+(Rotf/.1)`2)/2]|;
A44:    p1`1 = (Rotf/.1)`1 by EUCLID:52;
A45:    p1`2 = (b`2+(Rotf/.1)`2)/2 by EUCLID:52;
A46:    (Rotf/.1)`2 > (Rotf/.(1+1))`2 by A20,A25,A41,TOPREAL1:4;
        then (Rotf/.(1+1))`2 <= b`2 by A20,A25,TOPREAL1:4;
        then (Rotf/.(1+1))`2 < p1`2 by A45,A43,XXREAL_0:2;
        then
A47:    p1 in Lf by A1,A5,A39,A44,A45,A42,GOBOARD7:7,SPPOL_2:17;
        (Rotf/.len Rotf)`2 <= (Rotf/.(len Rotf-'1))`2
        proof
A48:      (Rotf/.(len Rotf-'1))`2 < (Rotf/.(1+1))`2 or (Rotf/.(len Rotf-'
          1))`2 >= (Rotf/.(1+1))`2;
          assume (Rotf/.len Rotf)`2 > (Rotf/.(len Rotf-'1))`2;
          then
          Rotf/.2 in LSeg(Rotf/.(len Rotf-'1),Rotf/.(len Rotf)) or Rotf/.
(len Rotf-'1) in LSeg(Rotf/.2,Rotf/.1) by A33,A39,A40,A46,A48,GOBOARD7:7;
          then
          Rotf/.2 in {Rotf/.1} or Rotf/.(len Rotf-'1) in {Rotf/.1} by A4,A10,A2
,A25,A31,XBOOLE_0:def 4;
          then
          Rotf/.(1+1) = Rotf/.1 or Rotf/.(len Rotf-'1) = Rotf/.(len Rotf)
          by A33,TARSKI:def 1;
          hence contradiction by A24,A22,A9,A7,A8,Th5;
        end;
        then
A49:    (Rotf/.len Rotf)`2 <= a`2 by A31,A36,TOPREAL1:4;
        then p1`2 < a`2 by A33,A45,A42,XXREAL_0:2;
        then p1 in LSeg(b,a) by A26,A6,A38,A44,A45,A43,GOBOARD7:7;
        then p1 in LSeg(a,b) /\ Lf by A47,XBOOLE_0:def 4;
        then p1 in {a,b} by A11,JORDAN18:22;
        hence contradiction by A33,A45,A43,A42,A49,TARSKI:def 2;
      end;
      suppose
A50:    (Rotf/.1)`2 < a`2;
        then
A51:    (a`2+(Rotf/.1)`2)/2 < a`2 by XREAL_1:226;
A52:    (Rotf/.1)`2 < (a`2+(Rotf/.1)`2)/2 by A50,XREAL_1:226;
        set p1 = |[(Rotf/.1)`1,(a`2+(Rotf/.1)`2)/2]|;
A53:    p1`1 = (Rotf/.1)`1 by EUCLID:52;
A54:    p1`2 = (a`2+(Rotf/.1)`2)/2 by EUCLID:52;
A55:    (Rotf/.(len Rotf-'1))`2 > (Rotf/.len Rotf)`2 by A33,A31,A36,A50,
TOPREAL1:4;
        then a`2 <= (Rotf/.(len Rotf-'1))`2 by A31,A36,TOPREAL1:4;
        then p1`2 < (Rotf/.(len Rotf-'1))`2 by A54,A51,XXREAL_0:2;
        then
A56:    p1 in Lf by A1,A33,A31,A40,A53,A54,A52,GOBOARD7:7,SPPOL_2:17;
        (Rotf/.(1+1))`2 <= (Rotf/.1)`2
        proof
A57:      (Rotf/.(len Rotf-'1))`2 < (Rotf/.(1+1))`2 or (Rotf/.(len Rotf-'
          1))`2 >= (Rotf/.(1+1))`2;
          assume (Rotf/.(1+1))`2 > (Rotf/.1)`2;
          then
          Rotf/.2 in LSeg(Rotf/.(len Rotf-'1),Rotf/.(len Rotf)) or Rotf/.
(len Rotf-'1) in LSeg(Rotf/.2,Rotf/.1) by A33,A39,A40,A55,A57,GOBOARD7:7;
          then
          Rotf/.2 in {Rotf/.1} or Rotf/.(len Rotf-'1) in {Rotf/.1} by A4,A10,A2
,A25,A31,XBOOLE_0:def 4;
          then
          Rotf/.(1+1) = Rotf/.1 or Rotf/.(len Rotf-'1) = Rotf/.(len Rotf)
          by A33,TARSKI:def 1;
          hence contradiction by A24,A22,A9,A7,A8,Th5;
        end;
        then
A58:    b`2 <= (Rotf/.1)`2 by A20,A25,TOPREAL1:4;
        then b`2 < p1`2 by A54,A52,XXREAL_0:2;
        then p1 in LSeg(b,a) by A26,A6,A38,A53,A54,A51,GOBOARD7:7;
        then p1 in LSeg(a,b) /\ Lf by A56,XBOOLE_0:def 4;
        then p1 in {a,b} by A11,JORDAN18:22;
        hence contradiction by A54,A52,A51,A58,TARSKI:def 2;
      end;
    end;
    suppose
A59:  LSeg(Rotf,1) is vertical & LSeg(Rotf,len Rotf-'1) is horizontal;
      then
A60:  a`2 = (Rotf/.len Rotf)`2 by A31,A36,SPPOL_1:40;
      a`1 = (Rotf/.len Rotf)`1 by A26,A6,A13,A19,A33,A25,A59,JORDAN3:9
,SPPOL_1:41;
      then a = Rotf/.len Rotf by A60,TOPREAL3:6;
      then a in LSeg(Rotf/.1,Rotf/.2) by A33,RLTOPSP1:68;
      then LSeg(a,b) c= LSeg(Rotf/.1,Rotf/.2) by A20,A25,TOPREAL1:6;
      then p in Lf by A1,A30,A25,SPPOL_2:17;
      then p in LSeg(a,b) /\ Lf by A30,XBOOLE_0:def 4;
      then p in {a,b} by A11,JORDAN18:22;
      hence contradiction by A29,A28,TARSKI:def 2;
    end;
    suppose
A61:  LSeg(Rotf,1) is horizontal & LSeg(Rotf,len Rotf-'1) is vertical;
      then
A62:  b`2 = (Rotf/.1)`2 by A13,A19,A25,JORDAN3:9,SPPOL_1:40;
      b`1 = (Rotf/.1)`1 by A26,A6,A33,A31,A36,A61,SPPOL_1:41;
      then b = Rotf/.1 by A62,TOPREAL3:6;
      then b in LSeg(Rotf/.(len Rotf-'1),Rotf/.len Rotf) by A33,RLTOPSP1:68;
      then LSeg(a,b) c= LSeg(Rotf/.(len Rotf-'1),Rotf/.len Rotf) by A31,A36,
TOPREAL1:6;
      then p in Lf by A1,A30,A31,SPPOL_2:17;
      then p in LSeg(a,b) /\ Lf by A30,XBOOLE_0:def 4;
      then p in {a,b} by A11,JORDAN18:22;
      hence contradiction by A29,A28,TARSKI:def 2;
    end;
    suppose
A63:  LSeg(Rotf,1) is horizontal & LSeg(Rotf,len Rotf-'1)is horizontal;
      then
A64:  a`2 = (Rotf/.(len Rotf-'1))`2 by A31,A36,SPPOL_1:40;
      b`2 = (Rotf/.1)`2 by A13,A19,A25,A63,JORDAN3:9,SPPOL_1:40;
      hence contradiction by A29,A28,A3,A25,A31,A63,A64,SPRECT_3:9;
    end;
  end;
  a in Lf by A11,JORDAN18:17;
  then
A65: a in L~rf by A1,A35,A32,XBOOLE_0:def 3;
  len rf = len Rotf-'1 by FINSEQ_1:59,NAT_D:35;
  then 1+1 <= len rf by A24,A23,NAT_1:13;
  then
A66: b in LSeg(rf,1) by A20,SPPOL_2:3;
A67: LSeg(rf,1) c= L~rf by TOPREAL3:19;
  then reconsider BCut = B_Cut(rf,b,a) as S-Sequence_in_R2 by A11,A66,A65,
JORDAN18:20,JORDAN3:37;
A68: len BCut + 1 >= 1 by NAT_1:11;
  set Ga = GoB(BCut^'pion);
  now
    let n be Nat;
    assume
A69: n in dom BCut;
    then
A70: n <= len BCut by FINSEQ_3:25;
    dom BCut c= dom (BCut^'pion) by Th23;
    then consider i,j be Nat such that
A71: [i,j] in Indices GoB(BCut^'pion) and
A72: (BCut^'pion)/.n = GoB(BCut^'pion)*(i,j) by A69,GOBOARD2:14;
    take i,j;
    thus [i,j] in Indices Ga by A71;
    1 <= n by A69,FINSEQ_3:25;
    hence BCut/.n = Ga*(i,j) by A72,A70,FINSEQ_6:159;
  end;
  then consider BCut1 be FinSequence of TOP-REAL 2 such that
A73: BCut1 is_sequence_on Ga and
A74: BCut1 is being_S-Seq and
A75: L~BCut = L~BCut1 and
A76: BCut/.1 = BCut1/.1 and
A77: BCut/.len BCut = BCut1/.len BCut1 and
A78: len BCut <= len BCut1 by GOBOARD3:2;
  reconsider BCut1 as S-Sequence_in_R2 by A74;
A79: L~BCut1 c= L~rf by A67,A66,A65,A75,JORDAN5B:24;
A80: len BCut1 in dom BCut1 by FINSEQ_5:6;
A81: 1 in dom BCut1 by FINSEQ_5:6;
A82: now
    assume BCut1 is constant;
    then BCut1/.1 = BCut1/.len BCut1 by A81,A80,FINSEQ_6:def 11;
    then BCut1/.len BCut1 = b by A67,A66,A65,A76,Th19;
    hence contradiction by A11,A67,A66,A65,A77,Th20,JORDAN18:20;
  end;
  BCut/.len BCut = a by A67,A66,A65,Th20;
  then
A83: a in LSeg(BCut1/.(len BCut1-'1),BCut1/.len BCut1) by A77,RLTOPSP1:68;
A84: len BCut1 >= 1+1 by TOPREAL1:def 8;
  then
A85: len BCut1-1 >= 1 by XREAL_1:19;
  take BCut;
  thus BCut = B_Cut(Rotate(Cage(C,n),Cage(C,n)/. Index(South-Bound(p,L~Cage(C,
n)), Cage(C,n)))|(len Rotate(Cage(C,n),Cage(C,n)/. Index(South-Bound(p,L~Cage(C
  ,n)), Cage(C,n)))-'1),South-Bound(p,L~Cage(C,n)),North-Bound(p,L~Cage(C,n)));
A86: LSeg(a,b) /\ Lf = {a,b} by A11,JORDAN18:22;
  len BCut > 0 by NAT_1:3;
  then
A87: len BCut >= 0+1 by NAT_1:13;
  then
A88: (BCut^'pion)/.len BCut = BCut/.len BCut by FINSEQ_6:159
    .= a by A67,A66,A65,Th20
    .= pion/.1 by FINSEQ_4:17;
A89: len pion = 1+1 by FINSEQ_1:44;
  then
A90: len (BCut^'pion) + 1 = len BCut + (1+1) by FINSEQ_6:139
    .= len BCut + 1 + 1;
  then
A91: len BCut < len (BCut^'pion) by NAT_1:13;
  now
    let n be Nat;
    assume n in dom pion;
    then
A92: n in Seg 2 by FINSEQ_1:89;
    per cases by A92,FINSEQ_1:2,TARSKI:def 2;
    suppose
A93:  n = 1;
      len BCut in Seg len (BCut^'pion) by A91,A87,FINSEQ_1:1;
      then len BCut in dom (BCut^'pion) by FINSEQ_1:def 3;
      then consider i,j be Nat such that
A94:  [i,j] in Indices Ga and
A95:  (BCut^'pion)/.len BCut = Ga*(i,j) by GOBOARD2:14;
      take i,j;
      thus [i,j] in Indices Ga by A94;
      thus pion/.n = Ga*(i,j) by A88,A93,A95;
    end;
    suppose
A96:  n = 1+1;
      len BCut + 1 in dom (BCut^'pion) by A90,A68,FINSEQ_3:25;
      then consider i,j be Nat such that
A97:  [i,j] in Indices Ga and
A98:  (BCut^'pion)/.(len BCut + 1) = Ga*(i,j) by GOBOARD2:14;
      take i,j;
      thus [i,j] in Indices Ga by A97;
      thus pion/.n = Ga*(i,j) by A89,A96,A98,FINSEQ_6:160;
    end;
  end;
  then consider pion1 be FinSequence of TOP-REAL 2 such that
A99: pion1 is_sequence_on Ga and
A100: pion1 is being_S-Seq and
A101: L~pion = L~pion1 and
A102: pion/.1 = pion1/.1 and
A103: pion/.len pion = pion1/.len pion1 and
A104: len pion <= len pion1 by A27,GOBOARD3:2;
  reconsider pion1 as S-Sequence_in_R2 by A100;
A105: pion1/.len pion1 = b by A89,A103,FINSEQ_4:17
    .= BCut1/.1 by A67,A66,A65,A76,Th19;
A106: L~rf c= L~f by A1,TOPREAL3:20;
  then L~BCut1 c= Lf by A79;
  then L~BCut1 /\ LSeg(a,b) c= {a,b} by A86,XBOOLE_1:26;
  then L~BCut1 /\ L~pion1 c= {a,b} by A101,SPPOL_2:21;
  then L~BCut1 /\ L~pion1 c= {a,BCut1/.1} by A67,A66,A65,A76,Th19;
  then
A107: L~BCut1 /\ L~pion1 c= {BCut1/.1,pion1/.1} by A102,FINSEQ_4:17;
  len BCut1 > 1 by A84,NAT_1:13;
  then
A108: len BCut1-'1+1 = len BCut1 by XREAL_1:235;
A109: BCut1/.len BCut1 = a by A67,A66,A65,A77,Th20
    .= pion1/.1 by A102,FINSEQ_4:17;
  then
A110: BCut1^'pion1 is_sequence_on Ga by A99,A73,TOPREAL8:12;
A111: L~BCut1 c= Lf by A106,A79;
A112: now
    assume b in LSeg(BCut1,len BCut1 -' 1);
    then b in LSeg(BCut1/.(len BCut1-'1),BCut1/.len BCut1) by A85,A108,
TOPREAL1:def 3;
    then LSeg(a,b) c= LSeg(BCut1/.(len BCut1-'1),BCut1/.len BCut1) by A83,
TOPREAL1:6;
    then p in LSeg(BCut1/.(len BCut1-'1),BCut1/.len BCut1) by A30;
    then p in LSeg(BCut1,len BCut1-'1) by A85,A108,TOPREAL1:def 3;
    then p in L~BCut1 by SPPOL_2:17;
    then p in LSeg(a,b) /\ Lf by A30,A111,XBOOLE_0:def 4;
    then p in {a,b} by A11,JORDAN18:22;
    hence contradiction by A29,A28,TARSKI:def 2;
  end;
  LSeg(BCut1,len BCut1 -' 1) c= L~BCut1 by TOPREAL3:19;
  then LSeg(BCut1,len BCut1 -' 1) c= L~rf by A79;
  then
A113: LSeg(BCut1,len BCut1 -' 1) c= Lf by A106;
  LSeg(pion1,1) c= L~pion by A101,TOPREAL3:19;
  then LSeg(pion1,1) c= LSeg(a,b) by SPPOL_2:21;
  then LSeg(BCut1,len BCut1 -' 1) /\ LSeg(pion1,1) c= LSeg(a,b) /\ Lf by A113,
XBOOLE_1:27;
  then
A114: LSeg(BCut1,len BCut1 -' 1) /\ LSeg(pion1,1) c= {a,b} by A11,JORDAN18:22;
A115: LSeg(BCut1,len BCut1 -' 1) /\ LSeg(pion1,1) = { BCut1/.len BCut1 }
  proof
    thus LSeg(BCut1,len BCut1 -' 1) /\ LSeg(pion1,1) c= { BCut1/.len BCut1 }
    proof
      let x be object;
      assume
A116: x in LSeg(BCut1,len BCut1 -' 1) /\ LSeg(pion1,1);
      then x <> b by A112,XBOOLE_0:def 4;
      then x = a by A114,A116,TARSKI:def 2;
      then x = BCut1/.len BCut1 by A67,A66,A65,A77,Th20;
      hence thesis by TARSKI:def 1;
    end;
    let x be object;
    assume x in { BCut1/.len BCut1 };
    then
A117: x = BCut1/.len BCut1 by TARSKI:def 1;
    then x in LSeg(BCut1/.(len BCut1-'1),BCut1/.len BCut1) by RLTOPSP1:68;
    then
A118: x in LSeg(BCut1,len BCut1-'1) by A85,A108,TOPREAL1:def 3;
    x in LSeg(pion1/.1,pion1/.(1+1)) by A109,A117,RLTOPSP1:68;
    then x in LSeg(pion1,1) by A89,A104,TOPREAL1:def 3;
    hence thesis by A118,XBOOLE_0:def 4;
  end;
  take pion1;
  len <*a,b*> = 2 by FINSEQ_1:44;
  hence
  pion1 is_sequence_on GoB(BCut^'<*North-Bound(p,L~Cage(C,n)),South-Bound
(p,L~Cage(C,n))*>) & L~<*North-Bound(p,L~Cage(C,n)),South-Bound(p,L~Cage(C,n))
  *> = L~pion1 & pion1/.1 = North-Bound(p,L~Cage(C,n)) & pion1/.len pion1 =
  South-Bound(p,L~Cage(C,n)) & len pion1 >= 2 by A99,A101,A102,A103,A104,
FINSEQ_4:17;
  set g = BCut1^'pion1;
  now
    assume len BCut = 1;
    then BCut/.1 = a by A67,A66,A65,Th20;
    hence contradiction by A12,A67,A66,A65,Th19;
  end;
  then len BCut > 1 by A87,XXREAL_0:1;
  then len BCut1 > 1 by A78,XXREAL_0:2;
  then
A119: len BCut1 >= 1+1 by NAT_1:13;
  {BCut1/.1,pion1/.1} c= L~BCut1 /\ L~pion1
  proof
    let x be object;
    assume x in {BCut1/.1,pion1/.1};
    then
A120: x = BCut1/.1 or x = pion1/.1 by TARSKI:def 2;
    then
A121: x in L~BCut1 by A109,A119,JORDAN3:1;
    x in L~pion1 by A89,A104,A105,A120,JORDAN3:1;
    hence thesis by A121,XBOOLE_0:def 4;
  end;
  then L~BCut1 /\ L~pion1 = {BCut1/.1,pion1/.1} by A107;
  then reconsider
  g as non constant standard special_circular_sequence by A109,A82,A110,A115
,A105,Th25,JORDAN8:4,TOPREAL8:11,33,34;
  take BCut1;
  thus BCut1 is_sequence_on GoB(BCut^'<*North-Bound(p,L~Cage(C,n)),South-Bound
  (p,L~Cage(C,n))*>) & L~BCut = L~BCut1 & BCut/.1 = BCut1/.1 & BCut/.len BCut =
  BCut1/.len BCut1 & len BCut <= len BCut1 by A73,A75,A76,A77,A78;
  take g;
  thus thesis;
end;
