reserve x,y for set;
reserve s,r for Real;
reserve r1,r2 for Real;
reserve n for Nat;
reserve p,q,q1,q2 for Point of TOP-REAL 2;

theorem Th45:
  for T,S,V being non empty TopSpace, P1 being non empty Subset of S,
  P2 being Subset of S,
  f being Function of T,S|P1, g being Function of S|P2,V st
  P1 c= P2 & f is continuous & g is continuous
  ex h being Function of T,V st h=g*f & h is continuous
proof
  let T,S,V be non empty TopSpace, P1 be non empty Subset of S,
  P2 be Subset of S, f be Function of T,S|P1, g be Function of S|P2,V;
  assume that
A1: P1 c= P2 and
A2: f is continuous and
A3: g is continuous;
  reconsider P3 = P2 as non empty Subset of S by A1,XBOOLE_1:3;
A4: [#](S|P1)=P1 by PRE_TOPC:def 5;
A5: [#](S|P2)=P2 by PRE_TOPC:def 5;
  then reconsider f1=f as Function of T,S|P3 by A1,A4,FUNCT_2:7;
  for F1 being Subset of S|P2 st F1 is closed holds f1"F1 is closed
  proof
    let F1 be Subset of S|P2;
    assume
A6: F1 is closed;
    reconsider P19=P1 as non empty Subset of S|P3 by A1,A5;
A7: [#](S|P1)=P1 by PRE_TOPC:def 5;
    reconsider P4=F1/\P19 as Subset of (S|P3)|P19 by TOPS_2:29;
A8: S|P1=(S|P3)|P19 by A1,PRE_TOPC:7;
A9: P4 is closed by A6,Th2;
    f1"P1=the carrier of T by A7,FUNCT_2:40
      .=dom f1 by FUNCT_2:def 1;
    then f1"F1=f1"F1 /\ f1"P1 by RELAT_1:132,XBOOLE_1:28
      .=f"P4 by FUNCT_1:68;
    hence thesis by A2,A8,A9;
  end;
  then f1 is continuous;
  hence thesis by A3;
end;
