reserve E, F, G,S,T,W,Y for RealNormSpace;
reserve f,f1,f2 for PartFunc of S,T;
reserve Z for Subset of S;
reserve i,n for Nat;

theorem Th46:
  for E,F be RealNormSpace
  ex L10 be Lipschitzian LinearOperator of E,[:E,F:]
  st for dx be Point of E holds L10.dx = [dx,0.F]
proof
  let E,F be RealNormSpace;

  defpred P2[object , object] means
  ex dx be Point of E
  st dx = $1 & $2 = [dx,0.F];

  A1: for x be object st x in the carrier of E
      holds
      ex y be object
      st y in the carrier of [:E,F:] & P2[x,y]
  proof
    let x be object;
    assume x in the carrier of E;
    then reconsider V1 = x as Point of E;
    take y = [V1,0.F];
    thus thesis;
  end;

  consider L1 be Function of the carrier of E, the carrier of [:E,F:]
  such that
  A2: for x be object st x in the carrier of E
      holds P2[x, L1.x] from FUNCT_2:sch 1(A1);

  A3: for dx be Point of E holds L1.dx = [dx,0.F]
  proof
    let dx be Point of E;
    ex V1 be Point of E
    st V1 = dx & L1.dx = [V1,0.F] by A2;
    hence L1.dx = [dx,0.F];
  end;

  for x, y be Element of E
  holds L1.(x + y) = L1.x + L1.y
  proof
    let x, y be Element of E;
    A4: L1.x = [x,0.F] by A3;
    A5: L1.y = [y,0.F] by A3;

    thus L1.(x + y)
     = [x + y, 0.F] by A3
    .= [x + y, 0.F + 0.F] by RLVECT_1:4
    .= L1.x + L1.y by A4,A5,PRVECT_3:18;
  end;
  then A6: L1 is additive;

  for x be VECTOR of E, a be Real holds L1.(a*x) = a * L1.x
  proof
    let x be VECTOR of E, a be Real;
    A7: L1.x = [x,0.F] by A3;
    thus L1.(a*x)
     = [a*x, 0.F] by A3
    .= [a*x, a * 0.F] by RLVECT_1:10
    .= a * L1.x by A7,PRVECT_3:18;
  end;
  then reconsider L1 as LinearOperator of E,[:E,F:] by A6,LOPBAN_1:def 5;

  set K = 1;

  for x be VECTOR of E holds ||.L1.x.|| <= K * ||.x.||
  proof
    let x be VECTOR of E;
    L1.x = [x,0.F] by A3;
    then ||.L1.x.|| <= ||.x.|| + ||.0.F.|| by Th17;
    then ||.L1.x.|| <= K * ||.x.|| + 0 by NORMSP_1:1;
    hence thesis;
  end;

  then L1 is Lipschitzian by LOPBAN_1:def 8;
  hence thesis by A3;
end;
