 reserve R for finite Approximation_Space;
 reserve X,Y,Z for Subset of R;
 reserve kap for RIF of R;

theorem LastLemma:
  for X being finite set holds
    JaccardDist X = SteinhausGen (SymmetricDiffDist X, {}X)
  proof
    let X be finite set;
    set f = JaccardDist X;
    set g = SteinhausGen (SymmetricDiffDist X, {}X);
    for x being Element of [:bool X,bool X:] holds
      f.x = g.x
    proof
      let x be Element of [:bool X,bool X:];
      consider x1,x2 being object such that
T1:   x1 in bool X & x2 in bool X & x = [x1,x2] by ZFMISC_1:def 2;
      reconsider x1,x2 as Subset of X by T1;
      set h = SymmetricDiffDist X;
      set p = {}X;
V1:   h.(x1,p) = card (x1 \+\ p) by SymDist .= card x1;
V2:   h.(x2,p) = card (x2 \+\ p) by SymDist .= card x2;
V3:   h.(x1,x2) = card (x1 \+\ x2) by SymDist;
nn:   g.(x1,x2)
          = (2 * card (x1 \+\ x2)) / (card x1 + card x2 + card (x1 \+\ x2))
                by V3,V2,V1,SteinGen;
      f.(x1,x2) = card (x1 \+\ x2) / card (x1 \/ x2) by Similar2
         .= g.(x1,x2) by HoHo,nn;
      hence thesis by T1;
    end;
    hence thesis;
  end;
