
theorem
  for V being RealUnitarySpace, v being VECTOR of V, r being Real st the
  carrier of V <> {0.V} & r > 0 holds Sphere(v,r) is non empty
proof
  let V be RealUnitarySpace;
  let v be VECTOR of V;
  let r be Real;
  assume that
A1: the carrier of V <> {0.V} and
A2: r > 0;
  now
    per cases;
    suppose
A3:   v = 0.V;
      ex u being VECTOR of V st u <> 0.V
      proof
        not the carrier of V c= {0.V} by A1;
        then NonZero V <> {} by XBOOLE_1:37;
        then consider u being object such that
A4:     u in NonZero V by XBOOLE_0:def 1;
A5:     not u in {0.V} by A4,XBOOLE_0:def 5;
        reconsider u as VECTOR of V by A4;
        take u;
        thus thesis by A5,TARSKI:def 1;
      end;
      then consider u being VECTOR of V such that
A6:   u <> 0.V;
      set a = ||.u.||;
A7:   a <> 0 by A6,BHSP_1:26;
      set u9 = r*(1/a)*u;
A8:   a >= 0 by BHSP_1:28;
      ||.v-u9.|| = ||. -r*(1/a)*u .|| by A3
        .= ||. r*(1/a)*u .|| by BHSP_1:31
        .= |.r*(1/a).|*||.u.|| by BHSP_1:27;
      then ||.v-u9.|| = r*(1/a)*||.u.|| by A2,A8,ABSVALUE:def 1
        .= r by A7,XCMPLX_1:109;
      then u9 in {y where y is Point of V : ||.v - y.|| = r};
      hence thesis by BHSP_2:def 7;
    end;
    suppose
A9:   v <> 0.V;
      set a = ||.v.||;
A10:  a <> 0 by A9,BHSP_1:26;
      set u9 = (1-r/a)*v;
A11:  ||.v-u9.|| = ||. 1*v - (1-r/a)*v .|| by RLVECT_1:def 8
        .= ||. (1-(1-r/a))*v .|| by RLVECT_1:35
        .= |.r/a.|*||.v.|| by BHSP_1:27;
      a >= 0 by BHSP_1:28;
      then ||.v-u9.|| = r/a*a by A2,A11,ABSVALUE:def 1
        .= r/(a/a) by XCMPLX_1:81
        .= r by A10,XCMPLX_1:51;
      then u9 in {y where y is Point of V : ||.v - y.|| = r};
      hence thesis by BHSP_2:def 7;
    end;
  end;
  hence thesis;
end;
